Maxima 5.47post Manual

2.1 Functions and Variables for Bug Detection and Reporting

関数: run_testsuite ([options]) ¶

Maximaのテストスイートを走らせます。 望みの答えを生成したテストは「パス」とみなされます。 望みの答えを生成しないテストも同様ですが、既知のバグとしてマークされています。

run_testsuiteは、以下のオプションキーワード引数を取ります。

display_all

テストすべてを表示します。 通常は、テストが失敗しない限りテストを表示しません。 （デフォルトでは falseに設定されます。）

display_known_bugs

既知のバグとしてマークされているテストを表示します。 （デフォルトでは falseに設定されます。）

tests

これは、実行するテストのリストです。 それぞれのテストは文字列かシンボルで指定することができます。 デフォルトではテストすべてを実行します。 テストの完全な組は testsuite_filesで指定されています。

time

時間情報を表示します。 もし trueならそれぞれのテストファイルにかかった時間を表示します。 もし allなら display_allが trueの時、 それぞれ個々のテストにかかった時間を示します。 デフォルトはfalseで、時間情報を示しません。

例えば、 run_testsuite(display_known_bugs = true, tests=[rtest5])は、 テスト rtest5だけを走らせ、既知のバグとしてマークされているテストを表示します。

run_testsuite(display_all = true, tests=["rtest1", rtest1a])は、 テスト rtest1と rtest2を走らせ、 テストそれぞれを表示します。

run_testsuiteは、Maxima環境を変更します。 通常は、テストスクリプトは 既知の環境（すなわちユーザー定義の関数や変数のない環境）を確立するために killを実行し、 それからテストにふさわしい関数や変数を定義します。

run_testsuiteは doneを返します。

Debugging ·

オプション変数: testsuite_files ¶

testsuite_filesは run_testsuiteが実行するテスト一式です。 それは実行するテストを含むファイル名のリストです。 もしファイルの中のテストのいくつかが失敗することが既知なら、 ファイル名をリストする代わりに、 ファイル名と失敗するテスト番号を含むリストを使います。

例えば、以下はデフォルトのテスト一式の一部です:

 ["rtest13s", ["rtest14", 57, 63]]

これは、ファイル"rtest13s", "rtest14"から成るテストスイートを指定しますが、 "rtest14" は失敗することが既知の２つのテスト57と63を含みます。

Debugging · Global variables ·

関数: bug_report () ¶

MaximaとLispのバージョン番号を表示し、Maximaプロジェクトのバグレポートウェブサイトへのリンクを与えます。 バージョン情報はbuild_infoがレポートするものと同じです。

バグをレポートする時、 MaximaとLispのバージョン情報をバグレポートにコピーしてもらえると助かります。

bug_reportは空の文字列 ""を返します。

Debugging ·

関数: build_info () ¶

Maximaビルドのパラメータのまとめを表示します。

build_infoは空の文字列 ""を返します。 bug_report.も参照してください。

Debugging ·

3.1 Documentation

このMaximaのオンラインユーザーズマニュアルは、違った形でも見ることができます。 Maximaの対話プロンプトから?コマンド（すなわちdescribe関数）を使うと、テキスト形式でユーザーズマニュアルが表示されます。infoビューアを使うと、ユーザーズマニュアルは、infoハイパーテキストとして表示され、通常のウェブブラウザを使えば、ウェブページとして表示されます。

exampleはたくさんのMaxima関数の使用例を表示します。 例えば、

(%i1) example (integrate);

は、

(%i2) test(f):=block([u],u:integrate(f,x),ratsimp(f-diff(u,x)))
(%o2) test(f) := block([u], u : integrate(f, x),
                                         ratsimp(f - diff(u, x)))
(%i3) test(sin(x))
(%o3)                           0
(%i4) test(1/(x+1))
(%o4)                           0
(%i5) test(1/(x^2+1))
(%o5)                           0

という感じでさらに出力を表示します。

3.2 Functions and Variables for Help

関数: apropos (string) ¶

stringを含むMaxima上の名前を検索します。 例えば、apropos ("exp")は、 （expand, exp, exponentializeのように） expを名前の一部として含むフラグ、関数すべてのリストを返します。 このように、もしなにかの名前の一部だけ覚えていたなら、 このコマンドを使って名前の残りを見つけることができます。 同様に、 apropos ("tr_")とすれば、翻訳器に関係した多くのスイッチのリストを 見つけることができます。翻訳器に関係したスイッチのほとんどはtr_で始まります。

apropos("")は、Maximaの名前すべてのリストを返します。

もし名前が見つからなければ、aproposは空のリスト[]を返します。

例:

"gamma"を含むMaximaシンボルすべてを表示します:

(%i1) apropos("gamma");
(%o1) [%gamma, gamma, gammalim, gamma_expand, gamma_incomplete_lower, 
gamma_incomplete, gamma_incomplete_generalized, 
gamma_incomplete_regularized, Gamma, log_gamma, makegamma, 
prefer_gamma_incomplete,
gamma_incomplete_generalized_regularized]

Help ·

関数: demo (filename) ¶

filenameの中のMaxima式を評価し、結果を表示します。 demoはそれぞれの式を評価した後 停止し、 ユーザーがリターンキーを入力すると続きを実行します。 (Xmaximaで走らせている場合、 demoはセミコロン;に続けて改行を入力する必要があります。)

demoは、filnameのファイルを探すため、 ディレクトリfile_search_demoのリストを検索します。 もしファイルの拡張子が.demなら、拡張子は省略できます。 file_searchも参照してください。

demoは引数を評価します。 demoはデモンストレーションファイルの名前を返します。

例:

(%i1) demo ("disol");

batching /home/wfs/maxima/share/simplification/disol.dem
 At the _ prompt, type ';' followed by enter to get next demo
(%i2)                      load("disol")

_
(%i3)           exp1 : a (e (g + f) + b (d + c))
(%o3)               a (e (g + f) + b (d + c))

_
(%i4)                disolate(exp1, a, b, e)
(%t4)                         d + c

(%t5)                         g + f

(%o5)                   a (%t5 e + %t4 b)

_

Help · Console interaction · File input ·

関数: describe (string) ¶

関数: describe (string, exact) ¶

関数: describe (string, inexact) ¶

describe(string)はdescribe(string, exact)と同値です。

describe(string, exact)は（大文字小文字は区別せず）stringに等しいタイトルを持った項目があれば、それを見つけます。

describe(string, inexact)はタイトルの中にstringを含むすべての項目を見つけます。 もし複数あれば、Maximaはユーザーに項目を選択するよう尋ねます。

対話プロンプトでは、 ? foo(?とfooの間にスペース)は describe("foo", exact)と同値であり、 ?? fooはdescribe("foo", inexact)と同値です。

describe("", inexact)は、オンラインマニュアルでドキュメント化されたすべてのトピックのリストを出力します。

describeは引数をクォートします。 describeは、ドキュメントが見つかればtrueを返し、見つからなければfalseを返します。

Documentationも参照してください。

例:

(%i1) ?? integ
 0: Functions and Variables for Elliptic Integrals
 1: Functions and Variables for Integration
 2: Introduction to Elliptic Functions and Integrals
 3: Introduction to Integration
 4: askinteger  (Functions and Variables for Simplification)
 5: integerp  (Functions and Variables for Miscellaneous Options)
 6: integer_partitions  (Functions and Variables for Sets)
 7: integrate  (Functions and Variables for Integration)
 8: integrate_use_rootsof  (Functions and Variables for
    Integration)
 9: integration_constant_counter  (Functions and Variables for
    Integration)
 10: nonnegintegerp  (Functions and Variables for linearalgebra)
Enter space-separated numbers, `all' or `none': 7 8

 -- Function: integrate (<expr>, <x>)
 -- Function: integrate (<expr>, <x>, <a>, <b>)
     Attempts to symbolically compute the integral of <expr> with
     respect to <x>.  `integrate (<expr>, <x>)' is an indefinite
     integral, while `integrate (<expr>, <x>, <a>, <b>)' is a
     definite integral, [...]
     
 -- Option variable: integrate_use_rootsof
     Default value: `false'

     When `integrate_use_rootsof' is `true' and the denominator of
     a rational function cannot be factored, `integrate' returns
     the integral in a form which is a sum over the roots (not yet
     known) of the denominator.
     [...]

この例では、項目7と8を選択しました。 （[...]でほのめかされているように出力は省略されています。） allやnoneを入力すると、項目すべてを選択したり、１つも選ばなかったりできます。 それぞれaもしくはnと省略形を使うことができます。

Help · Console interaction ·

関数: example (topic) ¶

関数: example () ¶

example (topic)は、topicの例をいくつか表示します。 topicはシンボルもしくは文字列です。 ifやdo、lambdaのような演算子の例を得るには、引数は文字列でなければなりません。例えば、 example ("do")。 exampleは、大文字小文字を区別しません。トピックのほとんどは関数名です。

example ()はわかっているトピックすべてのリストを表示します。

例を含むファイル名は、グローバル変数manual_demoで与えられます。デフォルトは"manual.demo"です。

exampleは引数をクォートします。 exampleはエラーがあったり引数がなかったりしなければdoneを返します。 引数がない場合には わかっているトピックすべてのリストを表示します。

例:

(%i1) example(append);
(%i2) append([x+y,0,-3.2],[2.5e+20,x])
(%o2)                    [y + x, 0, - 3.2, 2.5e+20, x]
(%o2)                                done
(%i3) example("lambda");

(%i4) lambda([x,y,z],z^2+y^2+x^2)
                                           2    2    2
(%o4)                   lambda([x, y, z], z  + y  + x )
(%i5) %(1,2,a)
                                     2
(%o5)                               a  + 5
(%i6) a+2+1
(%o6)                                a + 3
(%o6)                                done

Help · Console interaction ·

オプション変数: manual_demo ¶

デフォルト値: "manual.demo"

manual_demoは、 関数exampleのための例が入っているファイルの名前を指定します。 exampleを参照してください。

Help · Global variables ·

4.1 Introduction to Command Line

4.2 Functions and Variables for Command Line

システム変数: __ ¶

__は、現在評価中の入力式です。 すなわち、入力式 exprが評価されている間、 __は exprです。

__は、入力が整理されたり評価されたりする前に入力式に割り当てられます。 しかし表示される時、__の値は（評価はされませんが）整理されます。

batchと loadは __を認識します。 batchが処理するファイル内では、 __は対話プロンプトでのそれと同じ意味になります。 loadが処理するファイル内では、 __は対話プロンプトやバッチファイルの中で直前に入力された入力式にバインドされています; __は処理中のファイル内の入力式にはバインドされません。 特に、 load (filename)が対話プロンプトからコールされた時、 __は、ファイルが処理されている間、 load (filename)にバインドされます。

_や %も参照してください。

例:

(%i1) print ("I was called as", __);
I was called as print(I was called as, __) 
(%o1)              print(I was called as, __)
(%i2) foo (__);
(%o2)                     foo(foo(__))
(%i3) g (x) := (print ("Current input expression =", __), 0);
(%o3) g(x) := (print("Current input expression =", __), 0)
(%i4) [aa : 1, bb : 2, cc : 3];
(%o4)                       [1, 2, 3]
(%i5) (aa + bb + cc)/(dd + ee + g(x));
                            cc + bb + aa
Current input expression = -------------- 
                           g(x) + ee + dd
                                6
(%o5)                        -------
                             ee + dd

Global variables ·

システム変数: _ ¶

_は直前の入力式です。 (例えば、%i1, %i2, %i3, …)

_は、入力が整理されたり評価されたりする前に、入力式に割り当てられます。 しかし、 _の値は、表示される時（評価はされませんが）整理されます。

batchと loadは _を認識します。 batchが処理するファイル内では、 _は対話プロンプトでのそれと同じ意味になります。 loadが処理するファイル内では、 _は、対話プロンプトやバッチファイルの中で、直前に入力された入力式にバインドされます; _は処理中のファイル内の入力式にはバインドされません。

__や %も参照してください。

例:

(%i1) 13 + 29;
(%o1)                          42
(%i2) :lisp $_
((MPLUS) 13 29)
(%i2) _;
(%o2)                          42
(%i3) sin (%pi/2);
(%o3)                           1
(%i4) :lisp $_
((%SIN) ((MQUOTIENT) $%PI 2))
(%i4) _;
(%o4)                           1
(%i5) a: 13$
(%i6) b: 29$
(%i7) a + b;
(%o7)                          42
(%i8) :lisp $_
((MPLUS) $A $B)
(%i8) _;
(%o8)                         b + a
(%i9) a + b;
(%o9)                          42
(%i10) ev (_);
(%o10)                         42

Console interaction · Global variables ·

システム変数: % ¶

%はMaximaが直前に計算した出力式です。 (例えば、 %o1, %o2, %o3, …) 出力の表示には無関係です。

batchと loadは%を認識します。 batchが処理するファイル内では、 %は対話プロンプトでのそれと同じ意味になります。 loadが処理するファイル内では、 %は、対話プロンプトやバッチファイルの中で、直前に計算された出力式にバインドされます; %は、処理中のファイル内の出力式にはバインドされません。

_, %%, %thも参照してください。

Console interaction · Global variables ·

システム変数: %% ¶

合成文、すなわちblock, lambda, もしくは(s_1, ..., s_n)の中で、 %%は前の文の値です。

合成文の最初の文もしくは合成文の外側では%%は未定義です。

%%は、batchや loadで認識され、 対話プロンプトでのそれと同じ意味になります。

%も参照してください。

例:

以下の二つの例は同じ結果になります。

(%i1) block (integrate (x^5, x), ev (%%, x=2) - ev (%%, x=1));
                               21
(%o1)                          --
                               2
(%i2) block ([prev], prev: integrate (x^5, x),
               ev (prev, x=2) - ev (prev, x=1));
                               21
(%o2)                          --
                               2

合成文は他の合成文を含むかもしれません。 文が単文か合成文かに関係なく、 %%は前の文の値です。

(%i3) block (block (a^n, %%*42), %%/6);
                                 n
(%o3)                         7 a

合成文の中ではブレイクプロンプトで%%の値を検査することができます。 ブレイクプロンプトは break関数を実行することで開きます。 例えば、以下の例で%%;を入力すると、42が出力されます。

(%i4) block (a: 42, break ())$

Entering a Maxima break point. Type 'exit;' to resume.
_%%;
42
_

Global variables ·

関数: %th (i) ¶

i番前の出力式の値。 すなわち、計算される次の式をn番目の出力とすると %th (m)は、(n - m)番目の出力です。

batchとloadは%thを認識されます。 batchが処理するファイル内では、 %thは、対話プロンプトでのそれと同じ意味になります。 loadが処理するファイル内では、 %thは、対話プロンプトやバッチファイルの中で、直前に計算された出力式にバインドされます; %thは、処理中のファイル内の出力式にはバインドされません。

%と %%も参照してください。

例:

batchファイルの中でとか、出力式のグループを参照する時%thは役立ちます。 この例はsを最後の5つの出力式の和に設定します。

(%i1) 1;2;3;4;5;
(%o1)                           1
(%o2)                           2
(%o3)                           3
(%o4)                           4
(%o5)                           5
(%i6) block (s: 0, for i:1 thru 5 do s: s + %th(i), s);
(%o6)                          15

Console interaction ·

特殊シンボル: ? ¶

関数名や変数名の前置としての?は、 名前が、Maximaの名前ではなくLispの名前であることを意味します。 例えば、?roundは、Lisp関数ROUNDを意味します。 この点に関して更に知るにはLisp and Maximaを参照してください。

表記? word (空白を空けて単語が続くクエスチョンマーク)は describe("word")と同値です。 クエスチョンマークは入力ラインの先頭になければいけません; そうでなければドキュメンテーションのリクエストとして認識されません。 describeも参照してください。

Help · Console interaction ·

特殊シンボル: ?? ¶

表記?? word(空白を空けて単語が続く??)は describe("word", inexact)と同値です。 クエスチョンマークは入力行の先頭になければいけません; そうでなければドキュメンテーションのリクエストとして認識されません。 describeも参照してください。

Help · Console interaction ·

オプション変数: inchar ¶

デフォルト値: %i

incharはユーザーが入力した式のラベルの前置です。 Maximaは、 incharとlinenumを連結することで、 入力式それぞれのラベルを自動的に構成します。

incharは単一文字である必要はなく、 任意の文字列もしくはシンボルを割り当てられます。 Maximaは内部的に前置の最初の文字だけを考慮するので、 前置inchar, outchar, linecharは異なる最初の文字を持たなければいけません。 そうでなければkill(inlables)のようないくつかのコマンドは期待通りに動きません。

labelsも参照してください。

例:

(%i1) inchar: "input";
(%o1)                         input
(input2) expand((a+b)^3);
                     3        2      2      3
(%o2)               b  + 3 a b  + 3 a  b + a
(input3)

Display flags and variables ·

システム変数: infolists ¶

デフォルト値: []

infolistsはMaximaに関する情報リストすべての名前のリストです。 これらは以下の通りです:

labels

すべてのバインドされた%i, %o, %tラベル

values

:や::や関数バインドが生成する、 ユーザー変数であって、Maximaオプションやスイッチでない、 すべてのバインドされたアトム

functions

:=やdefineが生成するすべてのユーザー定義関数

arrays

:, ::, または:=が生成するすべての宣言配列と未宣言配列

macros

::=が生成したすべてのユーザー定義マクロ関数

myoptions

(それらが後にデフォルト値に再設定されようがされまいが) ユーザーが再設定したすべてのオプション

rules

tellsimp, tellsimpafter, defmatch, またはdefruleが生成するすべてのユーザー定義パターンマッチングと整理規則

aliases

alias, ordergreat, orderless関数が生成するか、 declareを使ってアトムをnounとして宣言することで生成された、 ユーザー定義エーリアスを持つすべてのアトム

dependencies

dependsやgradef関数が生成する関数依存性を持つすべてのアトム

gradefs

gradef関数が生成するユーザー定義の導関数を持つすべての関数

props

declare関数で確立されるプロパティはもちろん、 atvalueやmatchdeclareなどが確立するプロパティで、 上で述べたもの以外の任意のプロパティを持つすべてのアトム

let_rule_packages

特別パッケージdefault_let_rule_packageに加えて すべてのユーザー定義let規則パッケージ (default_let_rule_packageは、 ユーザーが陽に設定していない時使われる規則パッケージの名前です。)

Declarations and inferences · Global variables ·

関数: kill (a_1, …, a_n) ¶

関数: kill (labels) ¶

関数: kill (inlabels, outlabels, linelabels) ¶

関数: kill (n) ¶

関数: kill ([m, n]) ¶

関数: kill (values, functions, arrays, …) ¶

関数: kill (all) ¶

関数: kill (allbut (a_1, …, a_n)) ¶

引数a_1, …, a_nからすべてのバインド（値、関数、配列、ルール）を解除します。 引数a_kはシンボルか配列要素を取り得ます。 a_kが配列要素の時、killは配列の他の要素には影響することなくその要素をアンバインドします。

いくつかの特殊な引数が認識されます。 例えば、kill (inlabels, functions, allbut (foo, bar))のように、異なる引数の種類が組み合わされます。

kill (labels)はそれまでに作られた入力、出力、中間式のラベルすべてをアンバインドします。 kill (inlabels)は incharの現在の値で始まる入力ラベルのみをアンバインドします。 同様に、 kill (outlabels)は outcharの現在の値で始まる出力ラベルのみをアンバインドし、 kill (linelabels)は linecharの現在の値で始まる中間式ラベルのみをアンバインドします。

kill (n)（nは整数）は入力、出力ラベルの最近のn個をアンバインドします。

kill ([m, n])は入力、出力ラベルmからnまでをアンバインドします。

kill (infolist)は infolistの中のすべての項目をアンバインドします。 ここで、infolistは（values, functions, arraysのような) infolistsの中の任意の項目です。 infolistsも参照してください。

kill (all)はinfolistsのすべての項目をアンバインドします。 kill (all)はグローバル変数をデフォルト値にリセットしません; この点に関してはresetを参照してください。

kill (allbut (a_1, ..., a_n))は、 a_1, ..., a_nを除いて すべてのinfolistsの中のすべての項目をアンバインドします。 kill (allbut (infolist))は infolist（infolistはvalues, functions, arraysなど） 上の項目を除いてすべての項目をアンバインドします。

バインドされたプロパティによって使われたメモリは、すべてのシンボルがプロパティからアンバインドされるまで解放されません。 特に、シンボルの値によって使われているメモリを解放するには、 シンボルそのもののアンバインドだけでなく、バインドされた値を表示する出力ラベルをアンバインドします。

killは引数をクォートします。 引数を評価するにはクォートクォート演算子''を使います。

kill (symbol)はシンボルのすべてのプロパティをアンバインドします。 対照的に、関数remvalue, remfunction, remarray, remruleは特定のプロパティをアンバインドします。

kilは常に、たとえ引数がバインドされていなくても、doneを返します。

Evaluation · Console interaction · Session management ·

関数: labels (symbol) ¶

システム変数: labels ¶

symbolで始まる入力、出力、中間式ラベルのリストを返します。 symbolは、inchar, outchar, もしくはlinecharの値が典型的です。 ラベル文字はパーセント記号ありでもあしでもかまいませんので、 例えば、iと%iは同じ結果になります。

もしsymbolで始まるラベルがなければ、labelsは空のリストを返します。

関数labelsは引数をクォートします。 引数を評価するにはクォートクォート演算子''を使います。 例えば， labels (''inchar)は、現在の入力ラベル文字で始まる入力ラベルを返します。

変数labelsは入力、出力、中間式ラベルのリストです。 inchar, outchar, もしくはlinecharが再定義されても、以前のラベルすべてを含みます。

デフォルトで、Maximaはそれぞれのユーザー入力式の結果を表示し、結果に出力ラベルが与えられます。 入力を;(セミコロン)の代わりに$(ドル記号)で終了することで、出力表示は抑制されます。 出力ラベルが構成され、結果にバインドされますが、表示されません。 ラベルは表示された出力ラベルと同じ方法で参照できます。 %や%%, %thも参照してください。

いくつかの関数では中間式ラベルが生成されることがあります。 フラグprogrammodeは solveや他の関数が式のリストを返す代わりに中間式ラベルを生成するかどうかを制御します。 ldisplayのようないくつかの他の関数は常に中間式ラベルを生成します。

incharやoutchar, linechar, infolistsも参照してください。

Display functions · Display flags and variables · Console interaction ·

オプション変数: linechar ¶

デフォルト値: %t

linecharは Maximaが生成する中間式のラベルの前置です。 Maximaは（もし表示されるなら） linecharとlinenumを連結することで 中間式それぞれのラベルを構成します。

linecharは単一文字である必要はなく、 任意の文字列もしくはシンボルを割り当てられます。 Maximaは内部的に 前置の最初の文字だけを考慮するので、 前置inchar, outchar, linecharは異なる最初の文字を持たなければいけません。 そうでなければ kill(inlables)のようないくつかのコマンドは期待通りに動きません。

中間式は表示されるかもしれませんし、表示されないかもしれません。 programmodeとlabelsも参照してください。

Display flags and variables ·

システム変数: linenum ¶

入力出力式の現在のペアの行番号。

Display flags and variables · Console interaction ·

システム変数: myoptions ¶

デフォルト値: []

myoptionsはユーザーが再設定したオプションすべてのリストです。 初期値に再設定されたか否かに関わらずです。

Global variables · Session management · Console interaction ·

オプション変数: nolabels ¶

デフォルト値: false

nolabelsはtrueであれば、 入力と出力結果のラベル（それぞれ%iと%o）は表示されますが、 ラベルは結果にバインドされず、labelsリストにも追加されません。 ラベルは結果にバインドされないので、 ガーベッジコレクションは結果が使ったメモリを回復することができます。

そうでなければ、入力と出力の結果のラベルは結果にバインドされ、labelsリストに追加されます。

中間式ラベル(%t)はnolabelsに影響されません; nolabelsがtrueでもfalseでも、中間式ラベルはバインドされ、labelsリストに追加されます。

batchやload、 labelsも参照してください。

Global flags · Session management ·

オプション変数: optionset ¶

デフォルト値: false

optionsetがtrueの時、Maximaは、Maximaオプションが再設定されるといつでも、メッセージを表示します。 もしユーザーがあるオプションの綴りが怪しく、割り当てた変数が本当にオプション変数か確認したいなら便利です。

例:

(%i1) optionset:true;
assignment: assigning to option optionset
(%o1)                         true
(%i2) gamma_expand:true;
assignment: assigning to option gamma_expand
(%o2)                         true

Global flags · Session management · Console interaction ·

オプション変数: outchar ¶

デフォルト値: %o

outcharはMaximaが計算した式のラベルの前置です。 outcharとlinenumを連結することで、 Maximaは計算された式それぞれのラベルを自動的に構成します。 outcharは、単一文字である必要はなく、 任意の文字列もしくはシンボルを割り当てられます。 Maximaは内部的に前置の最初の文字だけを考慮するので、 前置inchar, outchar, linecharは異なる最初の文字を持たなければいけません。 そうでなければ、kill(inlables)のようないくつかのコマンドは期待通りに動きません。

labelsも参照してください。

例:

(%i1) outchar: "output";
(output1)                    output
(%i2) expand((a+b)^3);
                     3        2      2      3
(output2)           b  + 3 a b  + 3 a  b + a
(%i3)

Display flags and variables ·

関数: playback () ¶

関数: playback (n) ¶

関数: playback ([m, n]) ¶

関数: playback ([m]) ¶

関数: playback (input) ¶

関数: playback (slow) ¶

関数: playback (time) ¶

関数: playback (grind) ¶

入力、出力、中間式を表示します。再計算はしません。 playbackはラベルにバインドされた式表示するだけです; （printやdescribeで表示されたテキストやエラーメッセージなど）他の出力は表示されません。 labelsも参照してください。

playbackは引数をクォートします。 引数を評価するにはクォートクォート演算子''を使います。 playbackは常にdoneを返します。

playback ()（引数なし）は今までに生成された入力、出力、中間式すべてを表示します。 たとえ計算時に$終端子で出力が抑制されていても、 出力式は表示されます。

playback (n)は最近のn個の式を表示します。 入力、出力、中間式それぞれを１と数えます。

playback ([m, n])は m番目からn番目までの入力、出力、中間式を表示します。

playback ([m])は playback ([m, m])と同値です; これは普通、入力と出力の式のペアを１つ表示します。

playback (input)は今までに生成された入力式をすべて表示します。

playback (slow)は式の間でポーズし、ユーザーが enterを入力するのを待ちます。 これは demoと似たような振る舞いです。 playback (slow)は、saveやstringoutと関連して、 役立つ式を取り出すために２次記憶ファイルを生成するときに便利です。

playback (time)はそれぞれの式の計算時間を表示します。

playback (grind)は入力式を grind関数と同じ形式で表示します。 出力式は grindオプションで影響を受けません。 grindを参照してください。

例えば、playback ([5, 10], grind, time, slow)のように、 引数を組み合わせられます。

Display functions · Console interaction ·

オプション変数: prompt ¶

デフォルト値: _

promptは、demo関数やplayback (slow)モード、 （breakで呼び出された）Maximaブレイクループのプロンプトシンボルです。

Global variables · Console interaction ·

関数: quit () ¶

Maximaセッションを終了します。 関数は、quitではなく、quit();もしくはquit()$として呼び出さなければいけないことに注意してください。

長い計算を中断するには control-Cをタイプしてください。 デフォルトの動作では Maximaプロンプトに戻ります。 もし*debugger-hook*がnilなら、 control-CはLispデバッガを開きます。 debuggingも参照してください。

Console interaction ·

関数: read (expr_1, …, expr_n) ¶

expr_1, …, expr_nを表示し、 コンソールから式１つを読み込み、評価された式を返します。 式はセミコロン;もしくはドル記号$で終了します。

readonlyも参照してください。

(%i1) foo: 42$ 
(%i2) foo: read ("foo is", foo, " -- enter new value.")$
foo is 42  -- enter new value. 
(a+b)^3;
(%i3) foo;
                                     3
(%o3)                         (b + a)

Console interaction ·

関数: readonly (expr_1, …, expr_n) ¶

expr_1, …, expr_nを表示し、 コンソールから式を１つ読み込み、 式を（評価せずに）返します。 式はセミコロン;もしくはドル記号$で終了します。

readも参照してください。

例:

(%i1) aa: 7$
(%i2) foo: readonly ("Enter an expression:");
Enter an expression: 
2^aa;
                                  aa
(%o2)                            2
(%i3) foo: read ("Enter an expression:");
Enter an expression: 
2^aa;
(%o3)                            128

Console interaction ·

関数: reset () ¶

多くのグローバル変数やオプション、いくつかの他の変数をデフォルト値に再設定します。

resetは Lispリスト*variable-initial-values*上の変数を処理します。 Lispマクロdefmvarは（他の動作の間に）このリストに変数を置きます。 すべてではありませんが多くのグローバル変数やオプションがdefmvarによって定義されており、 また、defmvarで定義されたいくつかの変数はグローバル変数でもオプションでもありません。

Session management ·

オプション変数: showtime ¶

デフォルト値: false

showtimeがtrueの時、出力式と一緒に計算時間と経過時間を表示します。

計算時間は常に記録されており、 showtimeがfalseの時でも、 timeやplaybackで計算時間を表示することができます。

timerも参照してください。

Display flags and variables · Debugging ·

関数: to_lisp () ¶

Maximaの下のLispシステムに入ります。(to-maxima)でMaximaに戻ります。

例:

関数を定義し、Maximaの下のLispシステムに入ります。 定義をプロパティリスト上で検査します。そして、関数定義を抽出し、因数分解し、 変数$resultに格納します。 変数はMaximaに戻った後、Maximaで使うことができます。

(%i1) f(x):=x^2+x;
                                  2
(%o1)                    f(x) := x  + x
(%i2) to_lisp();
Type (to-maxima) to restart, ($quit) to quit Maxima.

MAXIMA> (symbol-plist '$f)
(MPROPS (NIL MEXPR ((LAMBDA) ((MLIST) $X) 
                             ((MPLUS) ((MEXPT) $X 2) $X))))
MAXIMA> (setq $result ($factor (caddr (mget '$f 'mexpr))))
((MTIMES SIMP FACTORED) $X ((MPLUS SIMP IRREDUCIBLE) 1 $X))
MAXIMA> (to-maxima)
Returning to Maxima
(%o2)                         true
(%i3) result;
(%o3)                       x (x + 1)

Console interaction ·

システム変数: values ¶

初期値: []

valuesは（Maximaのオプションやスイッチではなく）バインドされたユーザー変数すべてのリストです。 リストは、:や::でバインドされたシンボルを含みます。

もし変数の値がコマンドkillや, remove, remvalueで削除されたら、 変数はvaluesから削除されます。

ユーザー定義関数のリストに関しては functionsを参照してください。

例:

最初、valuesはシンボルa, b, cを示しますが、 dも―それは値にバインドされていません―ユーザー関数fも示しません。 値は変数から削除されます。valuesは空のリストです。

(%i1) [a:99, b::a-90, c:a-b, d, f(x):= x^2];
                                           2
(%o1)              [99, 9, 90, d, f(x) := x ]
(%i2) values;
(%o2)                       [a, b, c]
(%i3) [kill(a), remove(b,value), remvalue(c)];
(%o3)                   [done, done, [c]]
(%i4) values;
(%o4)                          []

Evaluation · Global variables ·

4.3 Functions and Variables for Display

オプション変数: %edispflag ¶

デフォルト値: false

%edispflagがtrueの時、 Maximaは %eの負の指数乗を商として表示します。 例えば、%e^-xは 1/%e^xと表示されます。 exptdispflagも参照してください。

例:

(%i1) %e^-10;
                               - 10
(%o1)                        %e
(%i2) %edispflag:true$
(%i3) %e^-10;
                               1
(%o3)                         ----
                                10
                              %e

Exponential and logarithm functions · Display flags and variables ·

オプション変数: absboxchar ¶

デフォルト値: !

absboxcharは１行より広い式の回りに絶対値記号を描くのに使われる文字です。

例:

(%i1) abs((x^3+1));
                            ! 3    !
(%o1)                       !x  + 1!

Display flags and variables ·

関数: disp (expr_1, expr_2, …) ¶

displayのようですが、 等式ではなく引数の値だけが表示されます。 これは名前を持たない複雑な引数や引数の値だけに興味があって 名前には興味がない引数に役立ちます。

ldispとprintも参照してください。

例:

(%i1) b[1,2]:x-x^2$
(%i2) x:123$
(%i3) disp(x, b[1,2], sin(1.0));
                               123

                                  2
                             x - x

                        .8414709848078965

(%o3)                         done

Display functions ·

関数: display (expr_1, expr_2, …) ¶

左辺が未評価のexpr_iで、右辺が式の値の等式を行の中央に表示します。 この関数は、中間結果を表示するのにブロックやfor文の中で役立ちます。 displayの引数は、通常アトムや、添字付き変数、関数コールです。 dispも参照してください。

ldisplay, disp, ldispも参照してください。

例:

(%i1) b[1,2]:x-x^2$
(%i2) x:123$
(%i3) display(x, b[1,2], sin(1.0));
                             x = 123

                                      2
                         b     = x - x
                          1, 2

                  sin(1.0) = .8414709848078965

(%o3)                         done

Display functions ·

オプション変数: display2d ¶

デフォルト値: true

display2dがfalseの時、 コンソール表示は（２次元）形式ではなく文字列（１次元）形式です。

例:

(%i1) x/(x^2+1);
                               x
(%o1)                        ------
                              2
                             x  + 1
(%i2) display2d:false$
(%i3) x/(x^2+1);
(%o3) x/(x^2+1)

Display flags and variables ·

オプション変数: display_format_internal ¶

デフォルト値: false

display_format_internalがtrueの時、 式は数学的内部表現を隠すように変換されることなく表示されます。 表示はpartではなくinpartが返すものに対応します。

例:

User     part       inpart
a-b;      a - b     a + (- 1) b

           a            - 1
a/b;       -         a b
           b
                       1/2
sqrt(x);   sqrt(x)    x

          4 X        4
X*4/3;    ---        - X
           3         3

Display flags and variables ·

関数: dispterms (expr) ¶

exprをパーツ毎に一行ずつ使って表示します。 すなわち、最初にexprの演算子が表示され、 それぞれの項が別々に表示されます。 もしexprが他の方法で表示するには大きすぎるなら、 これは役に立ちます。 例えば、もしP1, P2, ...が非常に大きな式なら、 P1 + P2 + ...を一度に表示しようとする場合、 表示プログラムは保存の空き領域を使い尽くすかもしれません。 しかしながら、 dispterms (P1 + P2 + ...)は、 P1を表示し、その下にP2を表示し、という具合です。 disptermsを使わない時、 もし指数式がA^Bのように表示するには広すぎるなら、 それはexpt (A, B) (もしくはA^^Bの場合、ncexpt (A, B)）のように現れます。

Display functions ·

関数: expt (a, b) ¶

関数: ncexpt (a, b) ¶

もし指数式がa^bのように表示するには広すぎるなら、 expt (a, b) (もしくは、a^^bの場合、ncexpt (a, b) のように現れます。

exptやncexptは入力では認識されません。

オプション変数: exptdispflag ¶

デフォルト値: true

exptdispflagがtrueの時、 Maximaは式を商を使って負の指数の式を表示します。

例:

(%i1) exptdispflag:true;
(%o1)                         true
(%i2) 10^-x;
                                1
(%o2)                          ---
                                 x
                               10
(%i3) exptdispflag:false;
(%o3)                         false
(%i4) 10^-x;
                                - x
(%o4)                         10

Expressions · Display flags and variables ·

関数: grind (expr) ¶

オプション変数: grind ¶

関数grindは コンソールにMaximaへの入力に適した形でexprを印刷します。 grindはいつもdoneを返します。

exprが関数名やマクロ名の時、 grindは、名前だけでなく関数やマクロ定義を出力します。

stringも参照してください。 それは出力を印刷する代わりに文字列を返します。 grindは stringの出力より若干読みやすい方法で 式を印刷しようとします。

変数grindがtrueの時、 stringやstringoutの出力は grindのそれと同じフォーマットです; そうでなければ、それらの関数の出力を特別にフォーマットしようとはしません。 変数grindのデフォルト値はfalseです。

grindは playbackの引数としても指定できます。 grindが存在する時、 playbackは grind関数と同じフォーマットで入力式を印刷します。 そうでなければ、入力式を特にフォーマットしようとはしません。

grindは引数を評価します。

例:

(%i1) aa + 1729;
(%o1)                       aa + 1729
(%i2) grind (%);
aa+1729$
(%o2)                         done
(%i3) [aa, 1729, aa + 1729];
(%o3)                 [aa, 1729, aa + 1729]
(%i4) grind (%);
[aa,1729,aa+1729]$
(%o4)                         done
(%i5) matrix ([aa, 17], [29, bb]);
                           [ aa  17 ]
(%o5)                      [        ]
                           [ 29  bb ]
(%i6) grind (%);
matrix([aa,17],[29,bb])$
(%o6)                         done
(%i7) set (aa, 17, 29, bb);
(%o7)                   {17, 29, aa, bb}
(%i8) grind (%);
{17,29,aa,bb}$
(%o8)                         done
(%i9) exp (aa / (bb + 17)^29);
                                aa
                            -----------
                                     29
                            (bb + 17)
(%o9)                     %e
(%i10) grind (%);
%e^(aa/(bb+17)^29)$
(%o10)                        done
(%i11) expr: expand ((aa + bb)^10);
         10           9        2   8         3   7         4   6
(%o11) bb   + 10 aa bb  + 45 aa  bb  + 120 aa  bb  + 210 aa  bb
         5   5         6   4         7   3        8   2
 + 252 aa  bb  + 210 aa  bb  + 120 aa  bb  + 45 aa  bb
        9        10
 + 10 aa  bb + aa
(%i12) grind (expr);
bb^10+10*aa*bb^9+45*aa^2*bb^8+120*aa^3*bb^7+210*aa^4*bb^6
     +252*aa^5*bb^5+210*aa^6*bb^4+120*aa^7*bb^3+45*aa^8*bb^2
     +10*aa^9*bb+aa^10$
(%o12)                        done
(%i13) string (expr);
(%o13) bb^10+10*aa*bb^9+45*aa^2*bb^8+120*aa^3*bb^7+210*aa^4*bb^6\
+252*aa^5*bb^5+210*aa^6*bb^4+120*aa^7*bb^3+45*aa^8*bb^2+10*aa^9*\
bb+aa^10
(%i14) cholesky (A):= block ([n : length (A), L : copymatrix (A),
  p : makelist (0, i, 1, length (A))], for i thru n do
  for j : i thru n do
  (x : L[i, j], x : x - sum (L[j, k] * L[i, k], k, 1, i - 1),
  if i = j then p[i] : 1 / sqrt(x) else L[j, i] : x * p[i]),
  for i thru n do L[i, i] : 1 / p[i],
  for i thru n do for j : i + 1 thru n do L[i, j] : 0, L)$
(%i15) grind (cholesky);
cholesky(A):=block(
         [n:length(A),L:copymatrix(A),
          p:makelist(0,i,1,length(A))],
         for i thru n do
             (for j from i thru n do
                  (x:L[i,j],x:x-sum(L[j,k]*L[i,k],k,1,i-1),
                   if i = j then p[i]:1/sqrt(x)
                       else L[j,i]:x*p[i])),
         for i thru n do L[i,i]:1/p[i],
         for i thru n do (for j from i+1 thru n do L[i,j]:0),L)$
(%o15)                        done
(%i16) string (fundef (cholesky));
(%o16) cholesky(A):=block([n:length(A),L:copymatrix(A),p:makelis\
t(0,i,1,length(A))],for i thru n do (for j from i thru n do (x:L\
[i,j],x:x-sum(L[j,k]*L[i,k],k,1,i-1),if i = j then p[i]:1/sqrt(x\
) else L[j,i]:x*p[i])),for i thru n do L[i,i]:1/p[i],for i thru \
n do (for j from i+1 thru n do L[i,j]:0),L)

Display functions · Display flags and variables ·

オプション変数: ibase ¶

デフォルト値: 10

ibaseは Maximaが読む整数の基数です。

ibaseは2から(十進数で)36までの任意の整数を割り当てられます。 ibaseが10よりも大きい時、 数値は十進数字0から9に加えて、 ibaseディジットに必要なアルファベットA, B, C, …で構成されます。 最初のディジットが0から9の時だけ文字はディジットとして解釈されます。 大文字小文字は区別されません。 許容される最も大きな基数36の数値は0から9までとAからZまでから構成されます。

ibaseの値がいくつでも、 整数が小数点で終了する時は基数10として解釈されます。

obaseも参照してください。

例:

ibase less than 10.

(%i1) ibase : 2 $
(%i2) obase;
(%o2)                          10
(%i3) 1111111111111111;
(%o3)                         65535

10より大きなibase。 最初のディジットが0から9までの時だけ文字はディジットとして解釈されます。

(%i1) ibase : 16 $
(%i2) obase;
(%o2)                          10
(%i3) 1000;
(%o3)                         4096
(%i4) abcd;
(%o4)                         abcd
(%i5) symbolp (abcd);
(%o5)                         true
(%i6) 0abcd;
(%o6)                         43981
(%i7) symbolp (0abcd);
(%o7)                         false

整数が小数点で終了する時、基数10として解釈されます。

(%i1) ibase : 36 $
(%i2) obase;
(%o2)                          10
(%i3) 1234;
(%o3)                         49360
(%i4) 1234.;
(%o4)                         1234

Console interaction ·

関数: ldisp (expr_1, …, expr_n) ¶

式expr_1, ..., expr_nをコンソールに印刷出力として表示します。 ldispは 引数それぞれに中間式ラベルを割り当て、ラベルのリストを返します。

disp, display, ldisplayも参照してください。

例:

(%i1) e: (a+b)^3;
                                   3
(%o1)                       (b + a)
(%i2) f: expand (e);
                     3        2      2      3
(%o2)               b  + 3 a b  + 3 a  b + a
(%i3) ldisp (e, f);
                                   3
(%t3)                       (b + a)

                     3        2      2      3
(%t4)               b  + 3 a b  + 3 a  b + a

(%o4)                      [%t3, %t4]
(%i4) %t3;
                                   3
(%o4)                       (b + a)
(%i5) %t4;
                     3        2      2      3
(%o5)               b  + 3 a b  + 3 a  b + a

Display functions ·

関数: ldisplay (expr_1, …, expr_n) ¶

式expr_1, ..., expr_nをコンソールに印刷出力として表示します。 式それぞれは、 lhsがldisplayの引数の１つで、rhsがその値の、 形式lhs = rhsの等式として表示されます。 典型的には引数それぞれは変数です。 ldispは式それぞれに中間式ラベルを割り当て、ラベルのリストを返します。

display, dispも参照してください。

例:

(%i1) e: (a+b)^3;
                                   3
(%o1)                       (b + a)
(%i2) f: expand (e);
                     3        2      2      3
(%o2)               b  + 3 a b  + 3 a  b + a
(%i3) ldisplay (e, f);
                                     3
(%t3)                     e = (b + a)

                       3        2      2      3
(%t4)             f = b  + 3 a b  + 3 a  b + a

(%o4)                      [%t3, %t4]
(%i4) %t3;
                                     3
(%o4)                     e = (b + a)
(%i5) %t4;
                       3        2      2      3
(%o5)             f = b  + 3 a b  + 3 a  b + a

Display functions ·

オプション変数: linel ¶

デフォルト値: 79

linelはコンソールディスプレイの仮定された(文字単位の)幅です。 linelはユーザーによって任意の値に割り当てられます。 非常に小さい値や非常に大きな値は実用的ではありませんが。 エラーメッセージやdescribeの出力のように、 Maximaの組み込み関数が表示するテキストはlinelの影響を受けません。

Display flags and variables ·

オプション変数: lispdisp ¶

デフォルト値: false

lispdispがtrueの時、 Lispシンボルはクエスチョンマーク?を先頭文字として表示されます。 そうでなければ、Lispシンボルは先頭文字を持ちません。

例:

(%i1) lispdisp: false$
(%i2) ?foo + ?bar;
(%o2)                       foo + bar
(%i3) lispdisp: true$
(%i4) ?foo + ?bar;
(%o4)                      ?foo + ?bar

Display flags and variables ·

オプション変数: negsumdispflag ¶

デフォルト値: true

negsumdispflagがtrueの時、 x - yは - y + xでなくx - yと表示されます。 falseに設定すると、 ２つの式の違いに関する表示での特殊なチェックがされないようになります。 １つの応用は、例えば、a + %i*bとa - %i*bを同じ表示にすることです。

Display flags and variables ·

オプション変数: obase ¶

デフォルト値: 10

obaseはMaximaが表示する整数の基数です。

obaseは2から(十進数で)36までの任意の整数を割り当てられます。 obaseが10よりも大きい時、 数値は十進数字0から9に加えて、 必要な大文字アルファベットA, B, C, ...で構成されます。 もし先頭ディジットがそうでなければ文字なら、0ディジットが先頭に表示されます。 許容される最も大きな基数36の数値は0から9までとAからZまでから構成されます。

ibaseも参照してください。

例:

(%i1) obase : 2;
(%o1)                          10
(%i2) 2^8 - 1;
(%o10)                      11111111
(%i3) obase : 8;
(%o3)                          10
(%i4) 8^8 - 1;
(%o4)                       77777777
(%i5) obase : 16;
(%o5)                          10
(%i6) 16^8 - 1;
(%o6)                       0FFFFFFFF
(%i7) obase : 36;
(%o7)                          10
(%i8) 36^8 - 1;
(%o8)                       0ZZZZZZZZ

Display flags and variables · Console interaction ·

オプション変数: pfeformat ¶

デフォルト値: false

pfeformatがtrueの時、 整数の比は斜線（スラッシュ）文字で表示され、 整数分母nは掛け算項1/nとして先に表示されます。

(%i1) pfeformat: false$
(%i2) 2^16/7^3;
                              65536
(%o2)                         -----
                               343
(%i3) (a+b)/8;
                              b + a
(%o3)                         -----
                                8
(%i4) pfeformat: true$ 
(%i5) 2^16/7^3;
(%o5)                       65536/343
(%i6) (a+b)/8;
(%o6)                      1/8 (b + a)

Display flags and variables ·

オプション変数: powerdisp ¶

デフォルト値: false

powerdispがtrueの時、 べきを増やす順に項を使って和が表示されます。 例えば、 多項式は切り詰められたべき級数として表示され、 最初に定数項最後に最高次項となります。

デフォルトでは和の項はべきを減らす順に表示されます。

Display flags and variables ·

関数: print (expr_1, …, expr_n) ¶

expr_1, …, expr_nを１つ１つ、左から右へ評価し、 コンソールディスプレイの左端から表示します。

printが返す値は最後の引数の値です。 printは中間式ラベルを生成しません。

display, disp, ldisplay, ldispも参照してください。 これらの関数は一行ずつ１つの式を表示しますが、 printは一行に２つ以上の式を表示しようとします。

ファイルの中身を表示するには printfileを参照してください。

例:

(%i1) r: print ("(a+b)^3 is", expand ((a+b)^3), "log (a^10/b) is",
      radcan (log (a^10/b)))$
            3        2      2      3
(a+b)^3 is b  + 3 a b  + 3 a  b + a  log (a^10/b) is 

                                              10 log(a) - log(b) 
(%i2) r;
(%o2)                  10 log(a) - log(b)
(%i3) disp ("(a+b)^3 is", expand ((a+b)^3), "log (a^10/b) is",
      radcan (log (a^10/b)))$
                           (a+b)^3 is

                     3        2      2      3
                    b  + 3 a b  + 3 a  b + a

                         log (a^10/b) is

                       10 log(a) - log(b)

Display functions ·

オプション変数: sqrtdispflag ¶

デフォルト値: true

sqrtdispflagがfalseの時、 sqrtを指数1/2で表示するようにします。

Mathematical functions · Display flags and variables ·

オプション変数: stardisp ¶

デフォルト値: false

stardispがtrueの時 掛け算はオペランドの間のアスタリスク*で表示されます。

Display flags and variables ·

オプション変数: ttyoff ¶

デフォルト値: false

ttyoffがtrueの時、 出力式は表示されません。 出力式は計算され、ラベルに割り当てられます。 labelsを参照してください。

エラーメッセージやdescribeの出力のように、組み込みMaxima関数によって出力されたテキストは ttyoffの影響を受けません。

Display flags and variables ·

5.1 Numbers

• Introduction to Numbers
• Functions and Variables for Numbers

5.2 Strings

• Introduction to Strings
• Functions and Variables for Strings

(%i1) s_1 : "This is a string.";
(%o1)               This is a string.
(%i2) s_2 : "Embedded \"double quotes\" and backslash \\ characters.";
(%o2) Embedded "double quotes" and backslash \ characters.
(%i3) s_3 : "Embedded line termination
in this string.";
(%o3) Embedded line termination
in this string.
(%i4) s_4 : "Ignore the \
line termination \
characters in \
this string.";
(%o4) Ignore the line termination characters in this string.
(%i5) stringdisp : false;
(%o5)                         false
(%i6) s_1;
(%o6)                   This is a string.
(%i7) stringdisp : true;
(%o7)                         true
(%i8) s_1;
(%o8)                  "This is a string."

5.3 Constants

5.4 Functions and Variables for Constants

定数: %e ¶

%eはEuler数としても知られる自然対数の基数を表します。 %eの数値は倍精度浮動小数点数2.718281828459045d0です。

Constants ·

定数: %i ¶

%iは虚数単位sqrt(- 1)を表します。

Constants ·

定数: false ¶

falseは同じ名前のブーリアン定数を表します。 Maximaは、Lispの値NILでfalseを実装しています。

Constants ·

定数: %gamma ¶

Euler-Macheroni定数0.5772156649015329 ....

Constants ·

定数: ind ¶

indは有界で不定の結果を表します。

limitも参照してください。

例:

(%i1) limit (sin(1/x), x, 0);
(%o1)                          ind

Constants ·

定数: inf ¶

infは実数の正の無限大を表します。

Constants ·

定数: infinity ¶

infinityは複素数の無限大を表します。

Constants ·

定数: minf ¶

minfは実数のマイナスの（すなわち負の）無限大を表します。

Constants ·

定数: %phi ¶

%phiは黄金比と呼ばれる(1 + sqrt(5))/2を表します。 %phiの数値は倍精度浮動小数点数1.618033988749895d0です。

fibtophiは、%phiを使って フィボナッチ数fib(n)を表現します。

デフォルトでは、Maximaは %phiの代数的プロパティを知りません。 tellrat(%phi^2 - %phi - 1)とalgebraic: trueを評価した後、 ratsimpは %phiを含むいくつかの式を整理できます。

例:

fibtophiは、%phiを使って フィボナッチ数fib(n)を表現します。

(%i1) fibtophi (fib (n));
                           n             n
                       %phi  - (1 - %phi)
(%o1)                  -------------------
                           2 %phi - 1
(%i2) fib (n-1) + fib (n) - fib (n+1);
(%o2)          - fib(n + 1) + fib(n) + fib(n - 1)
(%i3) fibtophi (%);
            n + 1             n + 1       n             n
        %phi      - (1 - %phi)        %phi  - (1 - %phi)
(%o3) - --------------------------- + -------------------
                2 %phi - 1                2 %phi - 1
                                          n - 1             n - 1
                                      %phi      - (1 - %phi)
                                    + ---------------------------
                                              2 %phi - 1
(%i4) ratsimp (%);
(%o4)                           0

デフォルトでは、Maximaは %phiの代数的プロパティを知りません。 tellrat(%phi^2 - %phi - 1)とalgebraic: trueを評価した後、 ratsimpは %phiを含むいくつかの式を整理できます。

(%i1) e : expand ((%phi^2 - %phi - 1) * (A + 1));
                 2                      2
(%o1)        %phi  A - %phi A - A + %phi  - %phi - 1
(%i2) ratsimp (e);
                  2                     2
(%o2)        (%phi  - %phi - 1) A + %phi  - %phi - 1
(%i3) tellrat (%phi^2 - %phi - 1);
                            2
(%o3)                  [%phi  - %phi - 1]
(%i4) algebraic : true;
(%o4)                         true
(%i5) ratsimp (e);
(%o5)                           0

Constants ·

定数: %pi ¶

%piは直径に体する円周の比を表します。 %piの数値は倍精度浮動小数点数3.141592653589793d0です。

Constants ·

定数: true ¶

trueは同じ名前のブーリアン定数を表します。 MaximaはLispの値Tでtrueを実装しています。

Constants ·

定数: und ¶

undは未定義の結果を表します。

limitも参照してください。

例:

(%i1) limit (x*sin(x), x, inf);
(%o1)                          und

Constants ·

定数: zeroa ¶

zeroaはゼロの上の無限小を表します。 zeroaは式の中で使うことができます。 limitは無限小を含む式を整理します。

zerobとlimitも参照してください。

例:

limitは無限小を含む式を整理します:

(%i1) limit(zeroa);
(%o1)                           0
(%i2) limit(x+zeroa);
(%o2)                           x

Constants ·

定数: zerob ¶

zerobはゼロの下の無限小を表します。 zerobは式の中で使うことができます。 limitは無限小を含む式を整理します。

zeroaとlimitも参照してください。

Constants ·

5.5 Lists

• Introduction to Lists
• Functions and Variables for Lists

((MPLUS) $A 2)

[1, 2, 7, x+y]

((MLIST) 1  2  7  ((MPLUS)  $X $Y ))

((MLIST SIMP) 1 2 7 ((MPLUS SIMP) $X $Y))

5.6 Arrays

5.7 Functions and Variables for Arrays

関数: array (name, dim_1, …, dim_n) ¶

関数: array (name, type, dim_1, …, dim_n) ¶

関数: array ([name_1, …, name_m], dim_1, …, dim_n) ¶

n次元の配列を生成します。 nは5以下を取り得ます。 i番目の次元のための添字は0からdim_iまで動く整数です。

array (name, dim_1, ..., dim_n)は 一般的な配列を生成します。

array (name, type, dim_1, ..., dim_n)は 指定されたタイプの要素を持つ配列を生成します。 typeには 制限されたサイズの整数にはfixnumが使え、 また、浮動小数点にはflonumが使えます。

array ([name_1, ..., name_m], dim_1, ..., dim_n) は同じ次元のm個の配列を生成します。

もしユーザーが対応する配列を宣言する前に添字付き変数に割り当てたら、 未宣言配列が生成されます。 (ハッシュコーディングが添字上でされるので)別名ハッシュド配列と知られる未宣言配列は、 宣言配列よりもっと一般的です。 ユーザーは最大サイズを宣言せず、さらなる要素が値に割り当てられる時、ハッシュすることで それらは動的に成長します。 未宣言配列の添字は数である必要すらありません。 しかしながら、 配列がむしろ疎でないなら、 未宣言のまま放っておくより、可能な時に宣言した方がおそらく効率的です。 array関数は未宣言配列を宣言配列に変換するのに使うことができます。

Arrays ·

関数: arrayapply (A, [i_1, … i_n]) ¶

A [i_1, ..., i_n]を評価します。 ここで、Aは配列、i_1, …, i_nは整数です。

これは、最初の引数が関数の代わりに配列だということを除いて、 applyを連想させます。

Expressions · Arrays ·

関数: arrayinfo (A) ¶

配列Aに関する情報を返します。 引数Aは、宣言配列、未宣言(ハッシュド)配列、配列関数、または添字付き関数を取り得ます。

宣言配列では、 arrayinfoは、 アトムdeclaredと、次元数、それぞれの次元のサイズを含むリストを返します。 配列の要素は、バインドされたものもそうでないものも、listarrayで返されます。

未宣言配列(ハッシュド配列)では、 arrayinfoは、 アトムhashedと、添字の数、値を持つすべての要素の添字を含むリストを返します。 値は listarrayで返されます。

配列関数では、 arrayinfoは、 アトムhashedと、添字の数、 記憶された関数値がある添字の値すべてを含むリストを返します。 記憶された関数値は、listarrayで返されます。

添字付き関数では、、 arrayinfoは、 returns a list comprising the アトムhashedと、添字の数、 ラムダ式がある添字の値すべてを含むリストを返します。 ラムダ式は listarrayで返されます。

listarrayも参照してください。

例:

宣言配列に適用されたarrayinfoとlistarray。

(%i1) array (aa, 2, 3);
(%o1)                          aa

(%i2) aa [2, 3] : %pi;
(%o2)                          %pi

(%i3) aa [1, 2] : %e;
(%o3)                          %e

(%i4) arrayinfo (aa);
(%o4)                 [declared, 2, [2, 3]]

(%i5) listarray (aa);
(%o5) [#####, #####, #####, #####, #####, #####, %e, #####, 
                                        #####, #####, #####, %pi]

未宣言(ハッシュド)配列に適用されたarrayinfoとlistarray。

(%i1) bb [FOO] : (a + b)^2;
                                   2
(%o1)                       (b + a)

(%i2) bb [BAR] : (c - d)^3;
                                   3
(%o2)                       (c - d)

(%i3) arrayinfo (bb);
(%o3)               [hashed, 1, [BAR], [FOO]]

(%i4) listarray (bb);
                              3         2
(%o4)                 [(c - d) , (b + a) ]

配列関数に適用されたarrayinfoとlistarray。

(%i1) cc [x, y] := y / x;
                                     y
(%o1)                      cc     := -
                             x, y    x

(%i2) cc [u, v];
                                v
(%o2)                           -
                                u

(%i3) cc [4, z];
                                z
(%o3)                           -
                                4

(%i4) arrayinfo (cc);
(%o4)              [hashed, 2, [4, z], [u, v]]

(%i5) listarray (cc);
                              z  v
(%o5)                        [-, -]
                              4  u

添字付き関数に適用されたarrayinfoとlistarray。

(%i1) dd [x] (y) := y ^ x;
                                     x
(%o1)                     dd (y) := y
                            x

(%i2) dd [a + b];
                                    b + a
(%o2)                  lambda([y], y     )

(%i3) dd [v - u];
                                    v - u
(%o3)                  lambda([y], y     )

(%i4) arrayinfo (dd);
(%o4)             [hashed, 1, [b + a], [v - u]]

(%i5) listarray (dd);
                         b + a                v - u
(%o5)      [lambda([y], y     ), lambda([y], y     )]

Arrays ·

関数: arraymake (A, [i_1, …, i_n]) ¶

式A[i_1, ..., i_n]を返します。 結果は未評価の配列参照です。

arraymakeは、 戻り値は、未評価関数コールの代わりに未評価の配列参照だということを除いて、 funmakeを連想させます。

例:

(%i1) arraymake (A, [1]);
(%o1)                          A
                                1

(%i2) arraymake (A, [k]);
(%o2)                          A
                                k

(%i3) arraymake (A, [i, j, 3]);
(%o3)                       A
                             i, j, 3

(%i4) array (A, fixnum, 10);
(%o4)                           A

(%i5) fillarray (A, makelist (i^2, i, 1, 11));
(%o5)                           A

(%i6) arraymake (A, [5]);
(%o6)                          A
                                5

(%i7) ''%;
(%o7)                          36

(%i8) L : [a, b, c, d, e];
(%o8)                    [a, b, c, d, e]

(%i9) arraymake ('L, [n]);
(%o9)                          L
                                n

(%i10) ''%, n = 3;
(%o10)                          c

(%i11) A2 : make_array (fixnum, 10);
(%o11)          {Array:  #(0 0 0 0 0 0 0 0 0 0)}

(%i12) fillarray (A2, [1, 2, 3, 4, 5, 6, 7, 8, 9, 10]);
(%o12)          {Array:  #(1 2 3 4 5 6 7 8 9 10)}

(%i13) arraymake ('A2, [8]);
(%o13)                         A2
                                 8

(%i14) ''%;
(%o14)                          9

Expressions · Arrays ·

システム変数: arrays ¶

デフォルト値: []

arraysは割り当てられた配列のリストです。 これらは、arrayで宣言された配列、 (なにかw配列要素に割り当てられた)陰の定義で構成されたハッシュド配列、 :=とdefineで定義された配列関数を含みます。 make_arrayで定義された配列は含まれません。

array, arrayapply, arrayinfo, arraymake, fillarray, listarray, rearrayも参照してください。

例:

(%i1) array (aa, 5, 7);
(%o1)                          aa

(%i2) bb [FOO] : (a + b)^2;
                                   2
(%o2)                       (b + a)

(%i3) cc [x] := x/100;
                                   x
(%o3)                      cc  := ---
                             x    100

(%i4) dd : make_array ('any, 7);
(%o4)       {Array:  #(NIL NIL NIL NIL NIL NIL NIL)}

(%i5) arrays;
(%o5)                     [aa, bb, cc]

Arrays · Global variables ·

関数: fillarray (A, B) ¶

配列AをBから埋めます。 ここで、Bはリストか配列です。

もし生成時に特定のタイプがAのために宣言されたら、 その同じタイプの要素でだけ埋めることができます; もし違ったタイプの要素をコピーする試みがなされたらエラーです。

もし配列AとBの次元が違ったら、 Aは行優先順で埋められます。 もしBの中の要素が十分でないなら、 Aの残りを埋めるのに最後の要素が使われます。 もし多すぎるなら、残りは無視されます。

fillarrayは最初の引数を返します。

例:

9個の要素の配列を生成し、リストから埋めます。

(%i1) array (a1, fixnum, 8);
(%o1)                          a1

(%i2) listarray (a1);
(%o2)              [0, 0, 0, 0, 0, 0, 0, 0, 0]

(%i3) fillarray (a1, [1, 2, 3, 4, 5, 6, 7, 8, 9]);
(%o3)                          a1

(%i4) listarray (a1);
(%o4)              [1, 2, 3, 4, 5, 6, 7, 8, 9]

配列を埋めるのに要素が足らない時、 最後の要素が繰り返されます。 要素が多すぎる時、余分の要素は無視されます。

(%i1) a2 : make_array (fixnum, 8);
(%o1)             {Array:  #(0 0 0 0 0 0 0 0)}

(%i2) fillarray (a2, [1, 2, 3, 4, 5]);
(%o2)             {Array:  #(1 2 3 4 5 5 5 5)}

(%i3) fillarray (a2, [4]);
(%o3)             {Array:  #(4 4 4 4 4 4 4 4)}

(%i4) fillarray (a2, makelist (i, i, 1, 100));
(%o4)             {Array:  #(1 2 3 4 5 6 7 8)}

多次元配列は行優先順に埋められます。

(%i1) a3 : make_array (fixnum, 2, 5);
(%o1)        {Array:  #2A((0 0 0 0 0) (0 0 0 0 0))}

(%i2) fillarray (a3, [1, 2, 3, 4, 5, 6, 7, 8, 9, 10]);
(%o2)        {Array:  #2A((1 2 3 4 5) (6 7 8 9 10))}

(%i3) a4 : make_array (fixnum, 5, 2);
(%o3)     {Array:  #2A((0 0) (0 0) (0 0) (0 0) (0 0))}

(%i4) fillarray (a4, a3);
(%o4)     {Array:  #2A((1 2) (3 4) (5 6) (7 8) (9 10))}

Arrays ·

関数: listarray (A) ¶

配列Aの要素のリストを返します。 引数Aは、宣言配列、未宣言(ハッシュド)配列、配列関数、添字付き関数を取り得ます。

要素は行優先順にリストされます。 すなわち、要素は、最初のインデックスに従って振り分けられ、次に二番目のインデックスに従って、などなど。 インデックス値の振り分け順は、 orderlessが確立する順と同じです。

未宣言配列や、配列関数、添字付き関数では、 要素はarrayinfoが返すインデックス値に対応します。

宣言された一般配列のバインドされていない要素(すなわち、fixnumでもflonumでもない要素)は、 #####として返されます。 宣言されたfixnum配列またはflonum配列のバイドされていない要素は、 それぞれ0または0.0として返されます。 未宣言配列、配列関数、添字付き関数のバインドされていない要素は返されません。

例:

宣言配列に適用されたlistarrayとarrayinfo。

(%i1) array (aa, 2, 3);
(%o1)                          aa

(%i2) aa [2, 3] : %pi;
(%o2)                          %pi

(%i3) aa [1, 2] : %e;
(%o3)                          %e

(%i4) listarray (aa);
(%o4) [#####, #####, #####, #####, #####, #####, %e, #####, 
                                        #####, #####, #####, %pi]

(%i5) arrayinfo (aa);
(%o5)                 [declared, 2, [2, 3]]

未宣言(ハッシュド)配列に適用されたlistarrayとarrayinfo。

(%i1) bb [FOO] : (a + b)^2;
                                   2
(%o1)                       (b + a)

(%i2) bb [BAR] : (c - d)^3;
                                   3
(%o2)                       (c - d)

(%i3) listarray (bb);
                              3         2
(%o3)                 [(c - d) , (b + a) ]

(%i4) arrayinfo (bb);
(%o4)               [hashed, 1, [BAR], [FOO]]

配列関数に適用されたlistarrayとarrayinfo。

(%i1) cc [x, y] := y / x;
                                     y
(%o1)                      cc     := -
                             x, y    x

(%i2) cc [u, v];
                                v
(%o2)                           -
                                u

(%i3) cc [4, z];
                                z
(%o3)                           -
                                4

(%i4) listarray (cc);
                              z  v
(%o4)                        [-, -]
                              4  u

(%i5) arrayinfo (cc);
(%o5)              [hashed, 2, [4, z], [u, v]]

添字付き関数に適用されたlistarrayとarrayinfo。

(%i1) dd [x] (y) := y ^ x;
                                     x
(%o1)                     dd (y) := y
                            x

(%i2) dd [a + b];
                                    b + a
(%o2)                  lambda([y], y     )

(%i3) dd [v - u];
                                    v - u
(%o3)                  lambda([y], y     )

(%i4) listarray (dd);
                         b + a                v - u
(%o4)      [lambda([y], y     ), lambda([y], y     )]

(%i5) arrayinfo (dd);
(%o5)             [hashed, 1, [b + a], [v - u]]

Arrays ·

関数: make_array (type, dim_1, ..., dim_n) ¶

Lisp配列を生成し、返します。 typeは、any, flonum, fixnum, hashed, functionalを取り得ます。 n個のインデックスがあり、 i番目のインデックスは0からdim_i - 1まで動きます。

make_arrayのarrayに対する利点は、 戻り値が名前を持たないことであり、 一旦、それへのポインタが消えると、それも消えます。 例えば、もしy: make_array (...)なら、 yは領域を取るオブジェクトを指しますが、 y: falseの後、yはそのオブジェクトをもはや指さないので、 オブジェクトはガーベッジコレクトされることができます。

例:

(%i1) A1 : make_array (fixnum, 10);
(%o1)           {Array:  #(0 0 0 0 0 0 0 0 0 0)}

(%i2) A1 [8] : 1729;
(%o2)                         1729

(%i3) A1;
(%o3)          {Array:  #(0 0 0 0 0 0 0 0 1729 0)}

(%i4) A2 : make_array (flonum, 10);
(%o4) {Array:  #(0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0)}

(%i5) A2 [2] : 2.718281828;
(%o5)                      2.718281828

(%i6) A2;
(%o6) 
     {Array:  #(0.0 0.0 2.718281828 0.0 0.0 0.0 0.0 0.0 0.0 0.0)}

(%i7) A3 : make_array (any, 10);
(%o7) {Array:  #(NIL NIL NIL NIL NIL NIL NIL NIL NIL NIL)}

(%i8) A3 [4] : x - y - z;
(%o8)                      - z - y + x

(%i9) A3;
(%o9) {Array:  #(NIL NIL NIL NIL ((MPLUS SIMP) $X ((MTIMES SIMP)\
 -1 $Y) ((MTIMES SIMP) -1 $Z))
  NIL NIL NIL NIL NIL)}

(%i10) A4 : make_array (fixnum, 2, 3, 5);
(%o10) {Array:  #3A(((0 0 0 0 0) (0 0 0 0 0) (0 0 0 0 0)) ((0 0 \
0 0 0) (0 0 0 0 0) (0 0 0 0 0)))}

(%i11) fillarray (A4, makelist (i, i, 1, 2*3*5));
(%o11) {Array:  #3A(((1 2 3 4 5) (6 7 8 9 10) (11 12 13 14 15))
    ((16 17 18 19 20) (21 22 23 24 25) (26 27 28 29 30)))}

(%i12) A4 [0, 2, 1];
(%o12)                         12

Arrays ·

関数: rearray (A, dim_1, ..., dim_n) ¶

配列の次元を変えます。 新しい配列は 行優先順に古いものの配列で埋められます。 もし古い配列が小さすぎるなら、 残りの要素は、 配列のタイプに依って、 false, 0.0または0で埋められます。 配列のタイプは変えられません。

Arrays ·

関数: remarray (A_1, ..., A_n) ¶

関数: remarray (all) ¶

配列と関数に関連づけられた配列を削除し、占められた領域を開放します。 引数は、宣言配列、未宣言(ハッシュド)配列、配列関数、添字付き関数を取り得ます。

remarray (all)は、 グローバルリストarraysの中の項目すべてを削除します。

もしハッシュド配列の中の値を再定義することが望ましいなら、この関数を使うことが必要になるかもしれません。

remarrayは削除された配列のリストを返します。

remarrayはクォートします。

Arrays ·

関数: subvar (x, i) ¶

添字付き式x[i]を評価します。

subvarは引数を評価します。

arraymake (x, [i]は 式x[i]を構成しますが、 それを評価はしません。

例:

(%i1) x : foo $
(%i2) i : 3 $

(%i3) subvar (x, i);
(%o3)                         foo
                                 3

(%i4) foo : [aa, bb, cc, dd, ee]$

(%i5) subvar (x, i);
(%o5)                          cc

(%i6) arraymake (x, [i]);
(%o6)                         foo
                                 3

(%i7) ''%;
(%o7)                          cc

Expressions · Arrays ·

関数: subvarp (expr) ¶

もしexprが例えばa[i]のように添字された変数なら、trueを返します。

Predicate functions ·

オプション変数: use_fast_arrays ¶

もしtrueなら、配列の２つのタイプだけが認識されます:

1. 整数でインデックスされたいくつかの次元を持つができ、 情報入力としてLispまたはMaximaオブジェクトを保てるart-q配列(Common Lispでのt)。 そんな配列を構成するには、 a:make_array(any,3,4);を入力してください。 aは、12個の枠を持つ配列を値として持ち、インデックスはゼロベースです
2. もしb[x+1]:y^2を実行したら、生成された配列のデフォルト値でハッシュテーブル配列 (bはまだ配列でもリストでも行列でもありません – もしこれらの１つなら、x+1は、art-q配列やリスト、行列の有効な添字ではないので 、エラーが起こります。) (キーとしても知られている)インデックスは、任意のオブジェクトを取り得ます。 一度の１つのキーだけを取ります((b[x+1,u]:yはuを無視します。)。 参照は、b[x+1] ==> y^2によってされます。 もちろん、キーは、例えば、 b[[x+1,u]]:yが有効なように リストを取り得ます。 これは古いMaximaハッシュ配列と非互換ですが、コンシングを保ちます。

配列をシンボルの値として記憶することの利点は、 関数のローカル変数についての普通の慣例が配列にも適用することです。 ハッシュテーブルタイプは、 Maximaハッシャの古いタイプよりも 少ないコンシングを使い、もっと効率的です。 翻訳され、コンパイルされたコードに関する一貫した振る舞いを得るためには、 translate_fast_arraysをtrueに設定してください。

Arrays · Global flags ·

5.8 Structures

• Introduction to Structures
• Functions and Variables for Structures

6.1 Introduction to Expressions

変数名として使えないたくさんの予約語があります。 これらを使うと、不可解な構文法エラーの原因となります。

integrate            next           from                 diff            
in                   at             limit                sum             
for                  and            elseif               then            
else                 do             or                   if              
unless               product        while                thru            
step                                                                     

Maximaのほとんどのものは式です。 括弧で囲み、コンマで区切ることで、式の列が構成できます。 これは、C言語のコンマ式に似ています。

(%i1) x: 3$
(%i2) (x: x+1, x: x^2);
(%o2)                          16
(%i3) (if (x > 17) then 2 else 4);
(%o3)                           4
(%i4) (if (x > 17) then x: 2 else y: 4, y+x);
(%o4)                          20

ループが返す値はあまり役に立たないdoneですが、Maximaではループでさえ式です。

(%i1) y: (x: 1, for i from 1 thru 10 do (x: x*i))$
(%i2) y;
(%o2)                         done

ところが、本当に欲しいものは、たぶん、実際に値を戻すコンマ式の３番目の項を含むことで得られます。

(%i3) y: (x: 1, for i from 1 thru 10 do (x: x*i), x)$
(%i4) y;
(%o4)                        3628800

6.2 Nouns and Verbs

Maximaは「名詞(Noun)」演算子と「動詞(Verb)」演算子を区別します。 動詞は実行される演算子です。 名詞は式の中で、実行されずシンボルとして現れる演算子です。 デフォルトでは、関数名は動詞です。 動詞は、関数名をクォートすることで、また、nounify関数を適用することで、 名詞に変えることができます。 名詞は、verbify関数を適用することで動詞に変えることができます。 評価フラグnounsは、evを式の中の名詞を評価するようにします。

動詞形は、対応するLispシンボル上では、先頭のドル記号$で区別されます。 対照的に、 名詞形は、対応するLispシンボル上では、先頭のパーセント記号%で区別されます。 'integrateや（diffが返す）'derivativeのように、 いくつかの名詞は特別な表示プロパティを持ちますが、ほとんどは特別な表示を持ちません。 デフォルトでは、表示される時、関数の名詞と動詞形は同一です。 グローバルフラグnoundispは、 Maximaに、先頭のクォートマーク'で名詞形を表示させます。

noun, nouns, nounify, やverbifyも参照してください。

例:

(%i1) foo (x) := x^2;
                                     2
(%o1)                     foo(x) := x
(%i2) foo (42);
(%o2)                         1764
(%i3) 'foo (42);
(%o3)                        foo(42)
(%i4) 'foo (42), nouns;
(%o4)                         1764
(%i5) declare (bar, noun);
(%o5)                         done
(%i6) bar (x) := x/17;
                                     x
(%o6)                    ''bar(x) := --
                                     17
(%i7) bar (52);
(%o7)                        bar(52)
(%i8) bar (52), nouns;
                               52
(%o8)                          --
                               17
(%i9) integrate (1/x, x, 1, 42);
(%o9)                        log(42)
(%i10) 'integrate (1/x, x, 1, 42);
                             42
                            /
                            [   1
(%o10)                      I   - dx
                            ]   x
                            /
                             1
(%i11) ev (%, nouns);
(%o11)                       log(42)

6.3 Identifiers

Maximaの識別子は、アルファベット文字と、0から9までの数詞と、 バックスラッシュ\文字に続く任意の特別文字で構成されます。

もしバックスラッシュが先行するなら、数詞は、識別子の最初の文字となることができます。 ２番目や後の文字の数詞は、バックスラッシュが先行する必要はありません。

文字は、declare関数によってアルファベットと宣言することができます。 もし宣言されたら、識別子の中でバックスラッシュで先行する必要はありません。 アルファベット文字は、AからZまで, aから zまで, %,と_が初期設定です。

Maximaは大文字小文字を区別します。 識別子foo, FOO, とFooは別の物です。 この点に関してLisp and Maximaを参照してください。

Maximaの識別子は、ドル記号$で始まるLispのシンボルです。 Maximaの中で現れる時、他の任意のLispシンボルは、クエスチョンマーク?で始まります。 この点に関してLisp and Maximaを参照してください。

例:

(%i1) %an_ordinary_identifier42;
(%o1)               %an_ordinary_identifier42
(%i2) embedded\ spaces\ in\ an\ identifier;
(%o2)           embedded spaces in an identifier
(%i3) symbolp (%);
(%o3)                         true
(%i4) [foo+bar, foo\+bar];
(%o4)                 [foo + bar, foo+bar]
(%i5) [1729, \1729];
(%o5)                     [1729, 1729]
(%i6) [symbolp (foo\+bar), symbolp (\1729)];
(%o6)                     [true, true]
(%i7) [is (foo\+bar = foo+bar), is (\1729 = 1729)];
(%o7)                    [false, false]
(%i8) baz\~quux;
(%o8)                       baz~quux
(%i9) declare ("~", alphabetic);
(%o9)                         done
(%i10) baz~quux;
(%o10)                      baz~quux
(%i11) [is (foo = FOO), is (FOO = Foo), is (Foo = foo)];
(%o11)                [false, false, false]
(%i12) :lisp (defvar *my-lisp-variable* '$foo)
*MY-LISP-VARIABLE*
(%i12) ?\*my\-lisp\-variable\*;
(%o12)                         foo

6.4 Inequality

Maximaは、不等式演算子<, <=, >=, >, #, notequalを持ちます。 条件式の記述に関しては、ifを参照してください。

6.5 Functions and Variables for Expressions

関数: alias (new_name_1, old_name_1, …, new_name_n, old_name_n) ¶

(利用者もしくはシステム)関数や変数、配列等に対して別名を与えます。 任意の偶数個の引数を取ります。

Declarations and inferences ·

システム変数: aliases ¶

デフォルト値: []

aliasesは、 (alias, ordergreat, orderless関数によって、もしくは、 declareで アトムをnounに宣言することで、設定される) ユーザー定義のエーリアスを持つ アトムのリストです。

Declarations and inferences · Global variables ·

キーワード: allbut ¶

partコマンド(すなわち、part,inpart,substpart, substinpart,dpart, lpart)と共に動作します。例えば、

(%i1) expr : e + d + c + b + a;
(%o1)                   e + d + c + b + a
(%i2) part (expr, [2, 5]);
(%o2)                         d + a

一方、

(%i1) expr : e + d + c + b + a;
(%o1)                   e + d + c + b + a
(%i2) part (expr, allbut (2, 5));
(%o2)                       e + c + b

killもallbutを認識します。

(%i1) [aa : 11, bb : 22, cc : 33, dd : 44, ee : 55];
(%o1)                 [11, 22, 33, 44, 55]
(%i2) kill (allbut (cc, dd));
(%o0)                         done
(%i1) [aa, bb, cc, dd];
(%o1)                   [aa, bb, 33, 44]

kill(allbut(a_1, a_2, ...))は、 シンボルa_1, a_2, …をキルしないよう除外して kill(all)を実行します。

関数: args (expr) ¶

exprの引数のリストを返します。 ここで、exprアトム以外のいかなる種類の式を取り得ます。 トップレベル演算子の引数だけが抽出されます; exprの部分式は、要素として、または、引数のリストの要素の部分式として現れます。

リストの中の項目の順序は、グローバルフラグinflagに依存するかもしれません。

args (expr)は、substpart ("[", expr, 0)と同値です。 substpartとopも参照してください。

Expressions ·

関数: atom (expr) ¶

もし exprがアトム(すなわち、数や名前や文字)なら、 true、そうでなければ falseを返します。 例えば、 atom(5)は trueですが、 (a[1]と xはバインドされていないと仮定して) atom(a[1])や atom(sin(x))は falseです。

Expressions · Predicate functions ·

関数: box (expr) ¶

関数: box (expr, a) ¶

枠で囲んだexprを返します。 返り値は、演算子としてboxを持ち、引数としてexprを持つ式です。 display2dがtrueの時、ディスプレイ上に枠が描かれます。

box (expr, a)は、 シンボルaでラベルされた枠でexprを囲みます。 もし枠の幅より長ければ、ラベルは切りつめられます。

boxは引数を評価します。 しかしながら、枠に入れられた式は中身に評価されないので、 枠に入れられた式は、計算から効果的に除外されます。

boxcharは、box, dpart, lpart関数において 枠を描くのに使われる文字です。

例:

(%i1) box (a^2 + b^2);
                            """""""""
                            " 2    2"
(%o1)                       "b  + a "
                            """""""""
(%i2) a : 1234;
(%o2)                         1234
(%i3) b : c - d;
(%o3)                         c - d
(%i4) box (a^2 + b^2);
                      """"""""""""""""""""
                      "       2          "
(%o4)                 "(c - d)  + 1522756"
                      """"""""""""""""""""
(%i5) box (a^2 + b^2, term_1);
                      term_1""""""""""""""
                      "       2          "
(%o5)                 "(c - d)  + 1522756"
                      """"""""""""""""""""
(%i6) 1729 - box (1729);
                                 """"""
(%o6)                     1729 - "1729"
                                 """"""
(%i7) boxchar: "-";
(%o7)                           -
(%i8) box (sin(x) + cos(y));
                        -----------------
(%o8)                   -cos(y) + sin(x)-
                        -----------------

Expressions ·

オプション変数: boxchar ¶

デフォルト値: "

boxcharは、box, dpart, lpart関数において 枠を描くのに使われる文字です。

式の中の枠すべては、boxcharの現在値で描かれます; 描画文字は枠式に保存されていません。

Expressions ·

関数: collapse (expr) ¶

共通の（すなわち等しい）部分式の全てを共用と（すなわち、同じセルを使用）させることで、 exprを縮約し、スペースを節約します。 (collapseは、optimizeコマンドによって使われるサブルーチンです。） 例えば，collapseをコールすることは、 saveファイルに積んだ後役に立つかもしれません。 collapse ([expr_1, ..., expr_n])を使うことで、いくつかの式を 一緒に縮約できます。 同様に、collapse (listarray ('A))を実行することで、配列Aの要素を縮約できます。

Expressions ·

関数: disolate (expr, x_1, …, x_n) ¶

ユーザーに１つ以上の変数を同時にisolate可能にさせることを除いて、 isolate (expr, x)に似ています。 例えば、もし多重積分の中で変数を変えようとしていて、それが２つ以上の積分変数を含んだ変数変換なら、これは役立つかもしれません。 この関数は、simplification/disol.macから自動ロードされます。 demo("disol")$でデモが入手可能です。

Expressions ·

関数: dispform (expr) ¶

関数: dispform (expr, all) ¶

exprの外部表現を返します。

dispform(expr)は、主（トップレベル）演算子に関して外部表現を返します。 dispform(expr, all)は、exprの中の演算子すべてに関して 外部表現を返します。

part, inpart, inflagも参照してください。

例:

- xの内部表現は、「-1掛けるx」ですが、 外部表現は、「マイナスx」です。

(%i1) - x;
(%o1)                          - x
(%i2) ?format (true, "~S~%", %);
((MTIMES SIMP) -1 $X)
(%o2)                         false
(%i3) dispform (- x);
(%o3)                          - x
(%i4) ?format (true, "~S~%", %);
((MMINUS SIMP) $X)
(%o4)                         false

sqrt(x)の内部表現は、「xの1/2乗」ですが、 外部表現は、「xの平方根」です。

(%i1) sqrt (x);
(%o1)                        sqrt(x)
(%i2) ?format (true, "~S~%", %);
((MEXPT SIMP) $X ((RAT SIMP) 1 2))
(%o2)                         false
(%i3) dispform (sqrt (x));
(%o3)                        sqrt(x)
(%i4) ?format (true, "~S~%", %);
((%SQRT SIMP) $X)
(%o4)                         false

オプション引数allの使用。

(%i1) expr : sin (sqrt (x));
(%o1)                     sin(sqrt(x))
(%i2) freeof (sqrt, expr);
(%o2)                         true
(%i3) freeof (sqrt, dispform (expr));
(%o3)                         true
(%i4) freeof (sqrt, dispform (expr, all));
(%o4)                         false

Expressions ·

関数: dpart (expr, n_1, …, n_k) ¶

partと同じ部分式を選択しますが、 その部分式を値として返すだけの代わりに、 枠の中に表示されて選択された部分式を持つ式全体を返します。 枠は実際に式の一部です。

(%i1) dpart (x+y/z^2, 1, 2, 1);
                             y
(%o1)                       ---- + x
                               2
                            """
                            "z"
                            """

Expressions ·

オプション変数: exptisolate ¶

デフォルト値: false

exptisolateがtrueの時、 isolate (expr, var)は、 varを含む(%eのような)アトムの指数を検査します。

Expressions ·

オプション変数: exptsubst ¶

デフォルト値: false

exptsubstがtrueの時、 %e^(a x)の中の%e^xへyを代入するような代入を許します。

Exponential and logarithm functions · Expressions ·

関数: freeof (x_1, …, x_n, expr) ¶

もしx_1と等しいexprの部分式がないか、 x_1がexprの中でダミー変数としてのみ現れるか、 x_1がexprの中で任意の演算子の名詞形でも動詞形でもないなら、 freeof (x_1, expr)は、trueを返します。 そうでなければ、falseを返します。

freeof (x_1, ..., x_n, expr)は、 freeof (x_1, expr)かつ、 ...かつfreeof (x_n, expr)と同値です。

引数x_1, …, x_n は、 関数や変数の名前、添字付き名前、（ダブルクォートでくくられた）演算子、もしくは一般式 を取り得ます。 freeofは引数を評価します。

freeofは、そのままは（整理と評価の後）expr上でのみ演算し、 ある同値の表現が違った結果を与えるかどうかを決定しようとはしません。 特に、整理は、同値ですが、exprの原型とは違った要素を含む異なる式を生成するかもしれません。

もし式の外部にバインドを持たなければ、変数は、式の中のダミー変数です。 freeofによって認識されたダミー変数は、 和や積のインデックス、limitの中の極限変数、 integrateの定積分形の中の積分変数、 laplaceの中のオリジナル変数、 at式の中の形式変数、 lambda式の中の引数です。

integrateの不定積分形は、積分変数から自由ではありません。

例:

引数は、関数、変数、添字付き名前、演算子、式の名前です。 freeof (a, b, expr)は freeof (a, expr) and freeof (b, expr)と同値です。

(%i1) expr: z^3 * cos (a[1]) * b^(c+d);
                                 d + c  3
(%o1)                   cos(a ) b      z
                             1
(%i2) freeof (z, expr);
(%o2)                         false
(%i3) freeof (cos, expr);
(%o3)                         false
(%i4) freeof (a[1], expr);
(%o4)                         false
(%i5) freeof (cos (a[1]), expr);
(%o5)                         false
(%i6) freeof (b^(c+d), expr);
(%o6)                         false
(%i7) freeof ("^", expr);
(%o7)                         false
(%i8) freeof (w, sin, a[2], sin (a[2]), b*(c+d), expr);
(%o8)                         true

freeofは引数を評価します。

(%i1) expr: (a+b)^5$
(%i2) c: a$
(%i3) freeof (c, expr);
(%o3)                         false

freeofは、同値の式を考慮しません。 整理は、同値ですが異なる式を生成します。

(%i1) expr: (a+b)^5$
(%i2) expand (expr);
          5        4       2  3       3  2      4      5
(%o2)    b  + 5 a b  + 10 a  b  + 10 a  b  + 5 a  b + a
(%i3) freeof (a+b, %);
(%o3)                         true
(%i4) freeof (a+b, expr);
(%o4)                         false
(%i5) exp (x);
                                 x
(%o5)                          %e
(%i6) freeof (exp, exp (x));
(%o6)                         true

和や定積分はダミー変数から自由です。 不定積分は積分変数から自由ではありません。

(%i1) freeof (i, 'sum (f(i), i, 0, n));
(%o1)                         true
(%i2) freeof (x, 'integrate (x^2, x, 0, 1));
(%o2)                         true
(%i3) freeof (x, 'integrate (x^2, x));
(%o3)                         false

Expressions ·

オプション変数: inflag ¶

デフォルト値: false

inflagがtrueの時、 部分抽出のための関数は、exprの内部形式を検査します。

整理器は式を再順序付けすることに注意してください。 例えば、 もしinflagがtrueなら、 first (x + y)は、xを返し、 もしif inflagがfalseなら、yを返します。 (first (y + x)は同じ結果を与えます。)

また、inflagをtrueに設定し、partやsubstpartをコールすることは、 inpartやsubstinpartをコールすることと同じです。

inflagの設定に影響される関数は以下の通りです: part, substpart, first, rest, last, length, for ... in構成子, map, fullmap, maplist, reveal, pickapart。

Expressions ·

関数: inpart (expr, n_1, ..., n_k) ¶

partに似ていますが、表示形式ではなく内部表現上で機能し、 フォーマットが実行されないのでより速いかもしれません。 （内部形式での変数の順序はしばしば表示形式でのそれと異なるので） 和や積の中の部分式の順序や、 （以下の演算子は式から取り除かれるので）単項マイナス、引き算、割り算を扱う際の部分式の順序 に関して注意が必要です。 part (x+y, 0)やinpart (x+y, 0)は、 +を返しますが、 演算子を参照するため、"で囲まれたものになります。 例えば、... if inpart (%o9,0) = "+" then ....

例:

(%i1) x + y + w*z;
(%o1)                      w z + y + x
(%i2) inpart (%, 3, 2);
(%o2)                           z
(%i3) part (%th (2), 1, 2);
(%o3)                           z
(%i4) 'limit (f(x)^g(x+1), x, 0, minus);
                                  g(x + 1)
(%o4)                 limit   f(x)
                      x -> 0-
(%i5) inpart (%, 1, 2);
(%o5)                       g(x + 1)

Expressions ·

関数: isolate (expr, x) ¶

和であり、中間式ラベル(それらは%t1, %t2, ...のようなアトムなシンボルです) で置き換えられたxを含まない部分式を含むexprを返します。 興味のある変数を含まない部分式の不必要な展開を避けるのに、これはしばしば役立ちます。 中間ラベルは部分式にバインドされているので、 それらが現れた式を評価することで、それらをすべて元に代入することができます。

もしexptisolate (デフォルト値: false)がtrueなら、 isolateは、xを含むか、(%eのような)アトムの指数を検査します。

もしisolate_wrt_timesがtrueなら、 isolateは積に関してもisolateします。 isolate_wrt_timesを参照してください。

サンプルを見るには、example (isolate)を実行してください。

Expressions ·

オプション変数: isolate_wrt_times ¶

デフォルト値: false

isolate_wrt_timesがtrueの時, isolateは、積に関してもisolateします。 例えば、スイッチの両方の設定を比較すると、

(%i1) isolate_wrt_times: true$
(%i2) isolate (expand ((a+b+c)^2), c);

(%t2)                          2 a


(%t3)                          2 b


                          2            2
(%t4)                    b  + 2 a b + a

                     2
(%o4)               c  + %t3 c + %t2 c + %t4
(%i4) isolate_wrt_times: false$
(%i5) isolate (expand ((a+b+c)^2), c);
                     2
(%o5)               c  + 2 b c + 2 a c + %t4

Expressions ·

オプション変数: listconstvars ¶

デフォルト値: false

listconstvarsがtrueの時、 listofvarsは、%e, %pi, %iや 定数と宣言された任意の変数を、 もしそれらが、listofvarsがコールされた式の中で現れたなら、 戻り値のリストの中に含みます。 デフォルトはこれらを省略します。

Expressions ·

オプション変数: listdummyvars ¶

デフォルト値: true

listdummyvarsがfalseの時、 式の中の「ダミー変数」は、listofvarsが返すリストの中に含まれません。 （「ダミー変数」の意味はfreeofで与えられているものです。 「ダミー変数」は、和や積のインデックスや、極限変数、定積分変数のように数学的なものです。）

例:

(%i1) listdummyvars: true$
(%i2) listofvars ('sum(f(i), i, 0, n));
(%o2)                        [i, n]
(%i3) listdummyvars: false$
(%i4) listofvars ('sum(f(i), i, 0, n));
(%o4)                          [n]

Expressions ·

関数: listofvars (expr) ¶

exprの中の変数のリストを返します。

もしlistconstvarsがtrueなら、 listofvarsは、%e, %pi, %iや 定数と宣言された任意の変数を、 もしそれらが、exprの中で現れたなら、 戻り値のリストの中に含みます。 デフォルトはこれらを省略します。

変数のリストのなかの「ダミー変数」を除外したり含めたりするには、オプション変数 listdummyvarsも参照してください。

(%i1) listofvars (f (x[1]+y) / g^(2+a));
(%o1)                     [g, a, x , y]
                                  1

Expressions ·

関数: lfreeof (list, expr) ¶

listのそれぞれのメンバーmに関して、 freeof (m, expr)をコールします。 もしfreeofのコールのいずれかがfalseを返すなら、 falseを返し、そうでなければ、trueを返します。

Expressions ·

関数: lpart (label, expr, n_1, …, n_k) ¶

dpartに似ていますが、ラベルされた枠を使います。 ラベルされた枠は、dpartによって生成されたものに似ていますが、 トップラインの中での名前を持ちます。

Expressions ·

宣言: mainvar ¶

変数をmainvarに宣言することができます。 アトムに関する順序付けスケールは本質的に以下の通りです: 数 < 定数 (例えば、%e, %pi) < スカラー < 他の変数 < mainvars。 例えば、(declare (x, mainvar), expand ((x+y)^4))を伴う expand ((X+Y)^4)。 （上の特長を使うことを選択したなら注意が必要なことに注意してください。 例えば、もし、 mainvarであるxを含む式を、mainvarでないxを含む式から引くなら、 もし打ち消しが起こるようにするなら、 例えばev (expr, simp)のような再整理が必要かもしれません。 また、mainvarであるxを含む式を保存するなら、 xもまた保存すべきです。）

Declarations and inferences · Expressions ·

宣言: noun ¶

nounは、declareコマンドのオプションの１つです。 関数を「名詞」に宣言するのに使います。 「名詞」は、自動的には評価されないことを意味します。

Nouns and verbs ·

オプション変数: noundisp ¶

デフォルト値: false

noundispがtrueの時、 名詞は、単一クォートで表示されます。 このスイッチは、関数定義を表示する時には、常にtrueです。

Display flags and variables · Nouns and verbs ·

関数: nounify (f) ¶

関数名fの名詞形を返します。 もし動詞関数の名前をまるで名詞のように参照したいなら、これが必要とされます。 もしある引数に関して関数が評価されないなら、 いくつかの動詞関数は名詞形を返すことに注意してください。 これは、クォートに関数コールが続く時、返される形式でもあります。

verbifyも参照してください。

Nouns and verbs ·

関数: nterms (expr) ¶

もし完全に展開されて、項の打ち消しや結合が起こらない場合の、exprが持つ 項の数を返します。 sin (expr), sqrt (expr), exp (expr), などのような式は、 exprが（もしそれが和なら） どんなにたくさんの項を持とうと、１項と数えます。

Expressions ·

関数: op (expr) ¶

式exprのメインの演算子を返します。 op (expr)はpart (expr, 0)と同値です。

opは、 もしメインの演算子が組み込みもしくはユーザー定義の前置、二項もしくはn項中置、後置、マッチフィックスもしくは無項演算子なら、文字列を返します。 そうでなければ、 もしexprが添字付き関数式なら、 opは添字付き関数を返します; この場合、戻り値はアトムではありません。 そうでなければ、 exprは配列関数もしくは通常の関数式であり、 opはシンボルを返します。

opはグローバルフラグinflagの値を見ています。

opは引数を評価します。

argsも参照してください。

例:

(%i1) stringdisp: true$
(%i2) op (a * b * c);
(%o2)                          "*"
(%i3) op (a * b + c);
(%o3)                          "+"
(%i4) op ('sin (a + b));
(%o4)                          sin
(%i5) op (a!);
(%o5)                          "!"
(%i6) op (-a);
(%o6)                          "-"
(%i7) op ([a, b, c]);
(%o7)                          "["
(%i8) op ('(if a > b then c else d));
(%o8)                         "if"
(%i9) op ('foo (a));
(%o9)                          foo
(%i10) prefix (foo);
(%o10)                        "foo"
(%i11) op (foo a);
(%o11)                        "foo"
(%i12) op (F [x, y] (a, b, c));
(%o12)                        F
                               x, y
(%i13) op (G [u, v, w]);
(%o13)                          G

Expressions · Operators ·

関数: operatorp (expr, op) ¶

関数: operatorp (expr, [op_1, …, op_n]) ¶

もしopがexprの演算子に等しければ、 operatorp (expr, op)はtrueを返します。

もしある要素op_1, ..., op_nがexprに等しければ、 operatorp (expr, [op_1, …, op_n])はtrueを返します。

Operators · Predicate functions ·

オプション変数: opsubst ¶

デフォルト値: true

opsubstがfalseの時、 substは、式の中の演算子に代入を試みません。 例えば、 (opsubst: false, subst (x^2, r, r+r[0]))は機能します。

Expressions ·

関数: optimize (expr) ¶

exprと同じ値と副作用を生成する式を返しますが、 共通の部分式の再計算を避けることによってより効率的に行います。 optimizeは、共通の部分式すべてが共用されるように引数を縮約する副作用も持ちます。 例を見るには、example (optimize)を実行してください。

Expressions ·

オプション変数: optimprefix ¶

デフォルト値: %

optimprefixはoptimizeコマンドによって生成されたシンボルのために 使われる前置です。

Expressions ·

関数: ordergreat (v_1, …, v_n) ¶

関数: orderless (v_1, …, v_n) ¶

ordergreatは、 v_1がv_2に続き、v_2は、…, v_nに続き、 そしてv_nは 引数として言及されなかった他の任意のシンボルに続くというように、 Maximaの式の標準の順序付けを変えます。

orderlessは、 v_1がv_2に先行し、v_2は、…, v_nに先行し、 そしてv_nは 引数として言及されなかった他の任意のシンボルに先行するというように、 Maximaの式の標準の順序付けを変えます。

ordergreatやorderlessによって確立される順序は、 unorderによって解消されます。 ordergreatやorderlessは、 unorderがコールされるまで、 それぞれ一度だけコールすることができます; ordergreatのorderlessの最後のコールだけが効果を持ちます。

ordergreatpも参照してください。

Expressions ·

関数: ordergreatp (expr_1, expr_2) ¶

関数: orderlessp (expr_1, expr_2) ¶

もしMaximaの式の標準の順序付けの中で、expr_1がexpr_2に続くなら、 ordergreatpは、trueを返し、 そうでなければ、falseを返します。

もしMaximaの式の標準の順序付けの中で、expr_1がexpr_2に先行するなら、 orderlesspは、trueを返し、 そうでなければ、falseを返します。

Maximaのアトムや式のすべては、ordergreatpとorderlesspの下で比較可能です。これらの述語論理が推移的でないような式の孤立した例はあるけれども; それはバグです。

アトム（シンボル、数リテラル、文字列）の標準の順序付けは以下の通りです。

(整数と浮動小数点)は以下に先行 (多倍長浮動小数点)は以下に先行 (宣言された定数)は以下に先行 (文字列)は以下に先行 (宣言されたスカラー)は以下に先行 (orderlessの最初の引数)は以下に先行 …は以下に先行 (orderlessの最後の引数) は以下に先行 (他のシンボル) は以下に先行 (ordergreatの最後の引数)は以下に先行 …は以下に先行 (ordergreatの最初の引数)は以下に先行 (宣言されたメイン変数)

アトムでない式に関して、標準の順序付けはアトムの順序付けから演繹されます。 組み込みの+ * ^演算子に関しては、 順序付けは簡単にはまとめられません。 他の組み込み演算子と他の半数や演算子、式すべてに関しては、 （最初の引数から始めて）それらの引数によって順序付けされ、 それから演算子や関数の名前によって順序付けされます。 添字付き式の場合、 添字付きのシンボルは演算子と、添字は引数と考えられます。

式の標準の順序付けは、関数ordergreatとorderlessと、 mainvar, constant, scalar宣言によって変更されます。

sortも参照してください。

例:

通常のシンボルや定数の順序付け。 %piは数値に従って順序付けされないことに注意してください。

(%i1) stringdisp : true;
(%o1)                         true
(%i2) sort([%pi, 3b0, 3.0, x, X, "foo", 3, a, 4, "bar", 4.0, 4b0]);
(%o2) [3, 3.0, 4, 4.0, 3.0b0, 4.0b0, %pi, "bar", "foo", a, x, X]

ordergreat、orderless関数の効果。

(%i1) sort ([M, H, K, T, E, W, G, A, P, J, S]);
(%o1)           [A, E, G, H, J, K, M, P, S, T, W]
(%i2) ordergreat (S, J);
(%o2)                         done
(%i3) orderless (M, H);
(%o3)                         done
(%i4) sort ([M, H, K, T, E, W, G, A, P, J, S]);
(%o4)           [M, H, A, E, G, K, P, T, W, J, S]

mainvar, constant, scalar宣言の効果

(%i1) sort ([aa, foo, bar, bb, baz, quux, cc, dd, A1, B1, C1]);
(%o1)   [aa, bar, baz, bb, cc, dd, foo, quux, A1, B1, C1]
(%i2) declare (aa, mainvar);
(%o2)                         done
(%i3) declare ([baz, quux], constant);
(%o3)                         done
(%i4) declare ([A1, B1], scalar);
(%o4)                         done
(%i5) sort ([aa, foo, bar, bb, baz, quux, cc, dd, A1, B1, C1]);
(%o5)   [baz, quux, A1, B1, bar, bb, cc, dd, foo, C1, aa]

アトムでない式の順序付け

(%i1) sort ([1, 2, n, f(1), f(2), f(2, 1), g(1), g(1, 2), g(n),
             f(n, 1)]);
(%o1) [1, 2, f(1), g(1), g(1, 2), f(2), f(2, 1), n, g(n), 
                                                         f(n, 1)]
(%i2) sort ([foo(1), X[1], X[k], foo(k), 1, k]);
(%o2)            [1, foo(1), X , k, foo(k), X ]
                              1              k

Expressions · Predicate functions ·

関数: part (expr, n_1, …, n_k) ¶

exprの表示形式のパーツを返します。 exprの最初のパーツn_1、それから、パーツn_2などなど、 結果は、exprのパーツn_1のパーツn_2の, ...パーツn_kです。 もし添字が指定されないなら、exprを返します。

partはリストの要素や行列の行を得るのに使うことができます。

もしpart関数の最後の引数がインデックスのリストなら、 それぞれがリストのインデックスに対応するいくつかの部分式が抽出されます。 従って、part (x + y + z, [1, 3])はz+xです。

pieceは、part関数を使ったとき、選択された最後の式を保持します。 それは関数の実行中にセットされ、以下で示すように、関数自身の中で参照されることもあります。

もしpartswitchがtrueに設定されているなら、 式の選択されたパーツが存在しないとき、endが返されます。 そうでなければ、エラーメッセージが出力されます。

inpart, substpart, substinpart, dpart, lpartも参照してください。

例:

(%i1) part(z+2*y+a,2);
(%o1)                                 2 y
(%i2) part(z+2*y+a,[1,3]);
(%o2)                                z + a
(%i3) part(z+2*y+a,2,1);
(%o3)                                  2

example (part)でさらに例を見ることができます。

Expressions ·

関数: partition (expr, x) ¶

２つの式のリストを返します。 それらは、 (1)（積なら）exprの因子、（和なら）expr項、 もしくは、（リストなら）xを含まないリストと、 (2)xを含む因子、項、リスト、 です。

例:

(%i1) partition (2*a*x*f(x), x);
(%o1)                     [2 a, x f(x)]
(%i2) partition (a+b, x);
(%o2)                      [b + a, 0]
(%i3) partition ([a, b, f(a), c], a); 
(%o3)                  [[b, c], [a, f(a)]]

Expressions ·

オプション変数: partswitch ¶

デフォルト値: false

partswitchがtrueの時、 式の選択された部分が存在しない時、endが返されます。 そうでない時は、エラーメッセージが出力されます。

Expressions ·

関数: pickapart (expr, n) ¶

中間式ラベルを、深さが整数nでのexprの部分式に割り当てます。 より大きなもしくは小さな深さでの部分式はラベルに割り当てられません。 pickapartは、元の式exprと同値の中間式の項による式を返します。

part, dpart, lpart, inpart, revealも参照してください。

例:

(%i1) expr: (a+b)/2 + sin (x^2)/3 - log (1 + sqrt(x+1));
                                          2
                                     sin(x )   b + a
(%o1)       - log(sqrt(x + 1) + 1) + ------- + -----
                                        3        2
(%i2) pickapart (expr, 0);

                                          2
                                     sin(x )   b + a
(%t2)       - log(sqrt(x + 1) + 1) + ------- + -----
                                        3        2

(%o2)                          %t2
(%i3) pickapart (expr, 1);

(%t3)                - log(sqrt(x + 1) + 1)


                                  2
                             sin(x )
(%t4)                        -------
                                3


                              b + a
(%t5)                         -----
                                2

(%o5)                    %t5 + %t4 + %t3
(%i5) pickapart (expr, 2);

(%t6)                 log(sqrt(x + 1) + 1)


                                  2
(%t7)                        sin(x )


(%t8)                         b + a

                         %t8   %t7
(%o8)                    --- + --- - %t6
                          2     3
(%i8) pickapart (expr, 3);

(%t9)                    sqrt(x + 1) + 1


                                2
(%t10)                         x

                  b + a              sin(%t10)
(%o10)            ----- - log(%t9) + ---------
                    2                    3
(%i10) pickapart (expr, 4);

(%t11)                     sqrt(x + 1)

                      2
                 sin(x )   b + a
(%o11)           ------- + ----- - log(%t11 + 1)
                    3        2

(%i11) pickapart (expr, 5);

(%t12)                        x + 1

                   2
              sin(x )   b + a
(%o12)        ------- + ----- - log(sqrt(%t12) + 1)
                 3        2
(%i12) pickapart (expr, 6);
                  2
             sin(x )   b + a
(%o12)       ------- + ----- - log(sqrt(x + 1) + 1)
                3        2

Expressions ·

システム変数: piece ¶

part関数を使った時選択された最後の式を返します。 関数の実行中に設定され、関数そのものの中で参照されることもあります。

Expressions ·

関数: psubst (list, expr) ¶

関数: psubst (a, b, expr) ¶

psubst(a, b, expr)はsubstに似ています。 substを参照してください。

substとは違って、 もし最初の引数listが等式のリストなら、 関数psubstは平行代入します。

並列代入するには、sublisも参照してください。

例:

最初の例は、 psubstを使った平行代入を示します。 二番目の例は、 関数substでの結果を示します。それは逐次代入します。

(%i4) psubst ([a^2=b, b=a], sin(a^2) + sin(b));
(%o4)                           sin(b) + sin(a)
(%i5) subst ([a^2=b, b=a], sin(a^2) + sin(b));
(%o5)                              2 sin(a)

Expressions ·

関数: rembox (expr, unlabelled) ¶

関数: rembox (expr, label) ¶

関数: rembox (expr) ¶

exprから枠を取り除きます。

rembox (expr, unlabelled)は、 exprからラベルされていない枠すべてを取り除きます。

rembox (expr, label)は、 labelを負う枠のみを取り除きます。

rembox (expr)は、ラベルされているか否か問わず、 枠すべてを取り除きます。

枠は、box, dpart, lpart関数によって描画されます。

例:

(%i1) expr: (a*d - b*c)/h^2 + sin(%pi*x);

                                  a d - b c
(%o1)                sin(%pi x) + ---------
                                      2
                                     h

(%i2) dpart (dpart (expr, 1, 1), 2, 2);
                        """""""    a d - b c
(%o2)               sin("%pi x") + ---------
                        """""""      """"
                                     " 2"
                                     "h "
                                     """"
(%i3) expr2: lpart (BAR, lpart (FOO, %, 1), 2);
                  FOO"""""""""""   BAR""""""""
                  "    """"""" "   "a d - b c"
(%o3)             "sin("%pi x")" + "---------"
                  "    """"""" "   "  """"   "
                  """"""""""""""   "  " 2"   "
                                   "  "h "   "
                                   "  """"   "
                                   """""""""""
(%i4) rembox (expr2, unlabelled);
                                  BAR""""""""
                   FOO"""""""""   "a d - b c"
(%o4)              "sin(%pi x)" + "---------"
                   """"""""""""   "    2    "
                                  "   h     "
                                  """""""""""
(%i5) rembox (expr2, FOO);
                                  BAR""""""""
                       """""""    "a d - b c"
(%o5)              sin("%pi x") + "---------"
                       """""""    "  """"   "
                                  "  " 2"   "
                                  "  "h "   "
                                  "  """"   "
                                  """""""""""
(%i6) rembox (expr2, BAR);
                   FOO"""""""""""
                   "    """"""" "   a d - b c
(%o6)              "sin("%pi x")" + ---------
                   "    """"""" "     """"
                   """"""""""""""     " 2"
                                      "h "
                                      """"
(%i7) rembox (expr2);
                                  a d - b c
(%o7)                sin(%pi x) + ---------
                                      2
                                     h

Expressions ·

関数: reveal (expr, depth) ¶

指定された整数depthのexprの部分を 記述的な要約で 置き換えます。

• 和と差分は、Sum(n)で置き換えられます。 ここで、nは、和のオペランドの数です。
• 積はProduct(n)で置き換えられます。 ここで、nは、積のオペランドの数です。
• 指数は、Exptで置き換えられます。
• 商は、Quotientで置き換えられます。
• 単項マイナスは、Negtermで置き換えられます。
• リストはList(n)で置き換えられます ここで、nはリストの要素の数です。

depthがexprの最大深さ以上の時、 reveal (expr, depth)は、exprをそのまま返します。

revealは、引数を評価します。 revealは、要約された式を返します。

例:

(%i1) e: expand ((a - b)^2)/expand ((exp(a) + exp(b))^2);
                          2            2
                         b  - 2 a b + a
(%o1)               -------------------------
                        b + a     2 b     2 a
                    2 %e      + %e    + %e
(%i2) reveal (e, 1);
(%o2)                       Quotient
(%i3) reveal (e, 2);
                             Sum(3)
(%o3)                        ------
                             Sum(3)
(%i4) reveal (e, 3);

                     Expt + Negterm + Expt
(%o4)               ------------------------
                    Product(2) + Expt + Expt

(%i5) reveal (e, 4);
                       2                 2
                      b  - Product(3) + a
(%o5)         ------------------------------------
                         Product(2)     Product(2)
              2 Expt + %e           + %e
(%i6) reveal (e, 5);
                         2            2
                        b  - 2 a b + a
(%o6)              --------------------------
                       Sum(2)     2 b     2 a
                   2 %e       + %e    + %e
(%i7) reveal (e, 6);
                          2            2
                         b  - 2 a b + a
(%o7)               -------------------------
                        b + a     2 b     2 a
                    2 %e      + %e    + %e

Expressions · Display functions ·

関数: sublis (list, expr) ¶

式に対して多重平行代入を行います。 listは等式のリストです。 等式の左辺はアトムでなければいけません。

変数sublis_apply_lambdaはsublisの後の式整理を制御します。

平行代入を行うには、psubstも参照してください。

例:

(%i1) sublis ([a=b, b=a], sin(a) + cos(b));
(%o1)                    sin(b) + cos(a)

Expressions ·

オプション変数: sublis_apply_lambda ¶

デフォルト値: true

lambdaの代入がsublisが使われた後の式整理の中で適用されるか 、もしくは、ユーザーが、ものに適用されるようにevを実行しなければいけないかを決めます。 trueは適用を意味します。

Expressions ·

オプション変数: subnumsimp ¶

デフォルト値: false

もしtrueなら、シンボルfが与えられた時だけ、 関数substとpsubstは添字付き変数f[x]に数を代入できます。

substも参照してください。

(%i1) subst(100,g,g[x]+2);

subst: cannot substitute 100 for operator g in expression g
                                                           x
 -- an error. To debug this try: debugmode(true);

(%i2) subst(100,g,g[x]+2),subnumsimp:true;
(%o2)                          102

Expressions ·

関数: subst (a, b, c) ¶

cの中のbにaを代入します。 bはアトムもしくはcの完全な部分式でなければなりません。 例えば、x+y+zは2*(x+y+z)の完全な部分式である一方、x+yは完全な部分式ではありません。 bがこれらの性質を持たない時は、substpartもしくはratsubstが使える時があります（下記参照）。 代わりに、もしbがe/f形式なら、subst (a*f, e, c)が使えますし、 もしbがe^(1/f)形式なら、subst (a^f, e, c)が使えます。 substコマンドはx^-yの中のx^yも認識するので、 subst (a, sqrt(x), 1/sqrt(x))は1/aを出力します。 aとbはダブルクォート"で囲まれた式の演算子でも、関数名でも問題ありません。 導関数形式の独立変数に代入したいなら、at関数（下記参照）を使うべきです。

substはsubstituteのエーリアスです。

コマンドsubst (eq_1, expr)もしくはsubst ([eq_1, ..., eq_k], expr)も許されている形式です。 eq_iはされるべき代入を指示する等式です。 それぞれの等式において、右辺が、式exprの中の左辺に代入されます。 等式は、exprに、左から右へ逐次に代入されます。 平行代入するには、関数sublisとpsubstを参照してください。

exptsubstがtrueなら、 %e^(a*x)の中の%e^xがyに置き換えられるような代入が許されます。

opsubstがfalseの時、 substは式の演算子への代入を行いません。 例えば、(opsubst: false, subst (X^2, r, r+r[9]))は意図通り動作します。

例:

(%i1) subst (a, x+y, x + (x+y)^2 + y);
                                    2
(%o1)                      y + x + a
(%i2) subst (-%i, %i, a + b*%i);
(%o2)                       a - %i b

代入は、等式のリストに関して逐次になされます。 これを並列代入と比較してください。

(%i3) subst([a=b, b=c], a+b);
(%o3)                                 2 c
(%i4) sublis([a=b, b=c], a+b);
(%o4)                                c + b

もっと例を見るには、example (subst)を実行してください。

Expressions ·

関数: substinpart (x, expr, n_1, ..., n_k) ¶

substpartと同様ですが、substinpartはexprの内部表現上で 働きます。

例:

(%i1) x . 'diff (f(x), x, 2);
                              2
                             d
(%o1)                   x . (--- (f(x)))
                               2
                             dx
(%i2) substinpart (d^2, %, 2);
                                  2
(%o2)                        x . d
(%i3) substinpart (f1, f[1](x + 1), 0);
(%o3)                       f1(x + 1)

もしpart関数の最後の引数がインデックスのリストなら、 複数の部分式が選ばれます。それぞれはリストのインデックスに対応します。 例えば、

(%i1) part (x + y + z, [1, 3]);
(%o1)                         z + x

part関数を使った時、pieceは、最後の式の値を保持します。 関数の実行の間に設定され、以下で示すように関数自身の中で参照されることもあります。 もしpartswitchがtrueに設定されたら、 式の選択された部分が存在しない時にはendが返されます。 そうでなければ、エラーメッセージが出力されます。

(%i1) expr: 27*y^3 + 54*x*y^2 + 36*x^2*y + y + 8*x^3 + x + 1;
              3         2       2            3
(%o1)     27 y  + 54 x y  + 36 x  y + y + 8 x  + x + 1
(%i2) part (expr, 2, [1, 3]);
                                  2
(%o2)                         54 y
(%i3) sqrt (piece/54);
(%o3)                        abs(y)
(%i4) substpart (factor (piece), expr, [1, 2, 3, 5]);
                               3
(%o4)               (3 y + 2 x)  + y + x + 1
(%i5) expr: 1/x + y/x - 1/z;
                             1   y   1
(%o5)                      - - + - + -
                             z   x   x
(%i6) substpart (xthru (piece), expr, [2, 3]);
                            y + 1   1
(%o6)                       ----- - -
                              x     z

また、 オプション inflagを trueに設定し partか substpartをコールすることは inpartか substinpartをコールすることと同じです。

Expressions ·

関数: substpart (x, expr, n_1, …, n_k) ¶

xを、残りの引数をpartに食わせた結果の部分式に代入します。 exprの新しい値を返します。 xはexprの演算子に代入される演算子でも問題ありません。 いくつかの場合、xはダブルクォート"で囲まれる必要があります。 （例えば、substpart ("+", a*b, 0)はb + aを返します。）

例:

(%i1) 1/(x^2 + 2);
                               1
(%o1)                        ------
                              2
                             x  + 2
(%i2) substpart (3/2, %, 2, 1, 2);
                               1
(%o2)                       --------
                             3/2
                            x    + 2
(%i3) a*x + f(b, y);
(%o3)                     a x + f(b, y)
(%i4) substpart ("+", %, 1, 0);
(%o4)                    x + f(b, y) + a

また、オプションinflagをtrueに設定し、 partやsubstpartをコールすることは、 inpartやsubstinpartをコールすることと同じになります。

Expressions ·

関数: symbolp (expr) ¶

もしexprがシンボルならtrue、そうでないならfalseを返します。 事実上、symbolp(x)は、述語論理atom(x) and not numberp(x)と同値です。

Identifiersも参照してください。

Predicate functions ·

関数: unorder () ¶

順序付けコマンドordergreatとorderlessの最後の使用で生成されたエーリアシングを使用不可にします。 ordergreatとorderlessは、 unorderを呼び出さずに、一回以上使えないかもしれません。 unorderは、 ordergreatとorderlessで導入されたエーリアスに 元のシンボルを式に再代入しません。 それ故に、unorderの実行後、以前の式にエーリアスが現れます。

ordergreatとorderlessも参照してください。

例s:

ordergreat(a)はシンボルaのエーリアスを導入します。 それ故に、 %o2と%o4の違いは消えません。 unorderはシンボルaを再代入しないし、 出力%o7にエーリアスが現れます。

(%i1) unorder();
(%o1)                          []
(%i2) b*x+a^2;
                                   2
(%o2)                       b x + a
(%i3) ordergreat(a);
(%o3)                         done
(%i4) b*x+a^2;
                             2
(%o4)                       a  + b x
(%i5) %th(1)-%th(3);
                              2    2
(%o5)                        a  - a
(%i6) unorder();
(%o6)                          [a]
(%i7) %th(2);
                                2    2
(%o7)                      _101a  - a

Expressions ·

関数: verbify (f) ¶

関数名fの動詞形を返します。 verb, noun, nounifyも参照してください。

例:

(%i1) verbify ('foo);
(%o1)                          foo
(%i2) :lisp $%
$FOO
(%i2) nounify (foo);
(%o2)                          foo
(%i3) :lisp $%
%FOO

Nouns and verbs ·

7.1 Introduction to operators

指定された優先順位を持つ新しい演算子を定義したり、 既存の演算子を未定義にしたり、既存の演算子の優先順位を再定義することが可能です。 演算子は単項前置、単項後置、二項中置、n項中置、マッチフィックスか無項でありえます。 「マッチフィックス」は引数を括るシンボルの対を意味し、 「無項」は引数を取らない演算子を意味します。 異なるタイプの演算子の例として、以下があります。

unary prefix

negation - a

unary postfix

factorial a!

binary infix

exponentiation a^b

n-ary infix

addition a + b

matchfix

list construction [a, b]

(組み込みの無項演算子はありません; そんな演算子の例は、nofixを参照してください。.)

新しい演算子を定義するメカニズムはわかりやすいものです。 関数を演算子として宣言することだけが必要です; 演算子関数は定義されることもされないこともあります。

ユーザー定義の演算子の例は以下の通りです。 明示的な関数コール "dd" (a)は dd aと同値であり、また、 "<-" (a, b)は a <- bと同値であることに注意してください。 この例で、 "dd"と "<-"は未定義です。

(%i1) prefix ("dd");
(%o1)                          dd
(%i2) dd a;
(%o2)                         dd a
(%i3) "dd" (a);
(%o3)                         dd a
(%i4) infix ("<-");
(%o4)                          <-
(%i5) a <- dd b;
(%o5)                      a <- dd b
(%i6) "<-" (a, "dd" (b));
(%o6)                      a <- dd b

新しい演算子を定義するMaxima関数はこの表にまとめられます。 デフォルトの左と右の結合力(それぞれlbpとrbp)を記載します。 (結合力は演算子の優先順位を決めます。 しかしながら、左と右の結合力は異なることがあり、 結合力は優先順位より幾分複雑です。) 演算定義関数のいくつかは追加の引数を取ります; 詳細は関数記述を参照してください。

prefix

rbp=180

postfix

lbp=180

infix

lbp=180, rbp=180

nary

lbp=180, rbp=180

matchfix

(binding power not applicable)

nofix

(binding power not applicable)

比較のために、いくつかの組み込み演算子と左右結合力を上げます。

Operator   lbp     rbp

  :        180     20 
  ::       180     20 
  :=       180     20 
  ::=      180     20 
  !        160
  !!       160
  ^        140     139 
  .        130     129 
  *        120
  /        120     120 
  +        100     100 
  -        100     134 
  =        80      80 
  #        80      80 
  >        80      80 
  >=       80      80 
  <        80      80 
  <=       80      80 
  not              70 
  and      65
  or       60
  ,        10
  $        -1
  ;        -1

removeと killは演算子プロパティをアトムから削除します。 remove ("a", op)は aの演算子プロパティだけを削除します。 kill ("a")は 演算子プロパティを含むaのすべてのロパティを削除します。 演算子名はクォーテーションマークで括らないといけないことに注意してください。

(%i1) infix ("##");
(%o1)                          ##
(%i2) "##" (a, b) := a^b;
                                     b
(%o2)                     a ## b := a
(%i3) 5 ## 3;
(%o3)                          125
(%i4) remove ("##", op);
(%o4)                         done
(%i5) 5 ## 3;
Incorrect syntax: # is not a prefix operator
5 ##
  ^
(%i5) "##" (5, 3);
(%o5)                          125
(%i6) infix ("##");
(%o6)                          ##
(%i7) 5 ## 3;
(%o7)                          125
(%i8) kill ("##");
(%o8)                         done
(%i9) 5 ## 3;
Incorrect syntax: # is not a prefix operator
5 ##
  ^
(%i9) "##" (5, 3);
(%o9)                       ##(5, 3)

7.2 Arithmetic operators

演算子: + ¶

演算子: - ¶

演算子: * ¶

演算子: / ¶

演算子: ^ ¶

シンボル + * / ^はそれぞれ、 足し算、かけ算、割り算、べき乗を表します。 これらの演算子の名前は "+" "*" "/" "^"です。 これらは関数や演算子の名前が求められるところで使います。

シンボル +や -はそれぞれ、プラスとマイナスの単項演算子を示し、 それらの名前はそれぞれ "+"と"-"です。

引き算 a - bはMaximaの中では足し算 a + (- b)として表されます。 a + (- b)のような式は引き算として表示されます。 Maximaは "-"を足し算の単項逆元演算子の名前としてのみ認識して、 二項引き算演算子としては認識しません。

Maximaの中では割り算a / bをかけ算a * b^(- 1)として表現します。 a * b^(- 1)のような式は割り算として表示されます。 Maximaは"/"を割り算演算子の名前として認識します。

足し算とかけ算はn項可換演算子です。 割り算とべき乗は二項の非可換演算子です。

Maximaは正準表現を構成するために可換演算子のオペランド(訳注：引数)を並べ替えます。 順序は内部的には orderlesspで決定します。 表示のためには、足し算の順序は ordergreatpで決定し、 かけ算は内部的な順序と同じです。

算術計算は、数リテラル（整数、有理数、通常の浮動小数点、多倍長浮動小数点）上で実行されます。 べき乗を除いて、数に対するすべての算術演算子は数に整理されます。 べき乗は、オペランドが通常の浮動小数点か多倍長浮動小数点の時、もしくは結果が厳密に整数もしくは有理数の時、数に整理されます; そうでなければ、べき乗は sqrtか他のべき乗に整理されるか、そのまま残されます。

浮動小数点の伝搬が算術計算に適用されます: もしどれか１つでもオペランドが多倍長浮動小数点なら、結果は多倍長浮動小数点です; そうでなければ、もしどれか１つでもオペランドが通常の浮動小数点なら、結果は通常の浮動小数点です; そうでなければオペランドは有理数か整数であり、結果は有理数か整数です。

算術計算は式整理であって、評価ではありません。 従って、クォートされた（しかし整理される）式の中で算術計算は実行されます。

算術演算は、 グローバルフラグ listarithが trueの時 リストに対して要素毎に適用され、 行列に対しては常に要素毎に適用されます。 オペランドの１つがリストか行列であり、もう１つのオペランドが別のタイプの時、 他のオペランドはリストか行列の要素のそれぞれに組み合わされます。

例:

足し算とかけ算は、n項可換演算子です。 Maximaは、正準表現を構成するために、可換演算子のオペランドを並べ替えます。 それらの名前はそれぞれ "+"と "*"です。

(%i1) c + g + d + a + b + e + f;
(%o1)               g + f + e + d + c + b + a
(%i2) [op (%), args (%)];
(%o2)              [+, [g, f, e, d, c, b, a]]
(%i3) c * g * d * a * b * e * f;
(%o3)                     a b c d e f g
(%i4) [op (%), args (%)];
(%o4)              [*, [a, b, c, d, e, f, g]]
(%i5) apply ("+", [a, 8, x, 2, 9, x, x, a]);
(%o5)                    3 x + 2 a + 19
(%i6) apply ("*", [a, 8, x, 2, 9, x, x, a]);
                                 2  3
(%o6)                       144 a  x

割り算とべき乗は、二項の非可換演算子です。 それらの名前はそれぞれ "/"と "^"です。

(%i1) [a / b, a ^ b];
                              a   b
(%o1)                        [-, a ]
                              b
(%i2) [map (op, %), map (args, %)];
(%o2)              [[/, ^], [[a, b], [a, b]]]
(%i3) [apply ("/", [a, b]), apply ("^", [a, b])];
                              a   b
(%o3)                        [-, a ]
                              b

引き算と割り算は内部的にはそれぞれ、足し算とかけ算を使って表現されます。

(%i1) [inpart (a - b, 0), inpart (a - b, 1), inpart (a - b, 2)];
(%o1)                      [+, a, - b]
(%i2) [inpart (a / b, 0), inpart (a / b, 1), inpart (a / b, 2)];
                                   1
(%o2)                       [*, a, -]
                                   b

計算は数リテラルに対して実行されます。 浮動小数点伝搬が適用されます。

(%i1) 17 + b - (1/2)*29 + 11^(2/4);
                                       5
(%o1)                   b + sqrt(11) + -
                                       2
(%i2) [17 + 29, 17 + 29.0, 17 + 29b0];
(%o2)                   [46, 46.0, 4.6b1]

算術計算は式整理であって、評価ではありません。

(%i1) simp : false;
(%o1)                         false
(%i2) '(17 + 29*11/7 - 5^3);
                              29 11    3
(%o2)                    17 + ----- - 5
                                7
(%i3) simp : true;
(%o3)                         true
(%i4) '(17 + 29*11/7 - 5^3);
                                437
(%o4)                         - ---
                                 7

算術計算は（listarithに依存して）リストや行列に対して要素毎に実行されます。

(%i1) matrix ([a, x], [h, u]) - matrix ([1, 2], [3, 4]);

                        [ a - 1  x - 2 ]
(%o1)                   [              ]
                        [ h - 3  u - 4 ]

(%i2) 5 * matrix ([a, x], [h, u]);

                          [ 5 a  5 x ]
(%o2)                     [          ]
                          [ 5 h  5 u ]
(%i3) listarith : false;
(%o3)                         false
(%i4) [a, c, m, t] / [1, 7, 2, 9];
                          [a, c, m, t]
(%o4)                     ------------
                          [1, 7, 2, 9]
(%i5) [a, c, m, t] ^ x;
                                      x
(%o5)                     [a, c, m, t]
(%i6) listarith : true;
(%o6)                         true
(%i7) [a, c, m, t] / [1, 7, 2, 9];
                              c  m  t
(%o7)                     [a, -, -, -]
                              7  2  9
(%i8) [a, c, m, t] ^ x;
                          x   x   x   x
(%o8)                   [a , c , m , t ]

Operators ·

演算子: ** ¶

べき乗演算子。 Maximaは入力の中で **を ^と同じ演算子と認識し、 1次元出力の中では ^として表示し、 また、2次元出力の中では指数を上付き添字として配置します。

fortran関数は、入力が **でも ^でも、 べき乗演算子を **として表示します。

例:

(%i1) is (a**b = a^b);
(%o1)                         true
(%i2) x**y + x^z;
                              z    y
(%o2)                        x  + x
(%i3) string (x**y + x^z);
(%o3)                        x^z+x^y
(%i4) fortran (x**y + x^z);
      x**z+x**y
(%o4)                         done

Operators ·

演算子: ^^ ¶

非可換べき乗演算子。 ちょうど可換なかけ算 *に通常のべき乗演算子 ^が対応するように、 ^^は非可換かけ算 .に対応するべき乗演算子です。

非可換べき乗演算子は、１次元出力では ^^で表示され、 ２次元出力では、指数をかっこ < >で囲まれた上付き添字として置きます。

例:

(%i1) a . a . b . b . b + a * a * a * b * b;
                        3  2    <2>    <3>
(%o1)                  a  b  + a    . b
(%i2) string (a . a . b . b . b + a * a * a * b * b);
(%o2)                  a^3*b^2+a^^2 . b^^3

Operators ·

演算子: . ¶

行列（非可換）かけ算のためのドット演算子。 "."をこの意味で用いる時、 例えば A . Bのように両側にスペースを置かなければいけません。 これで浮動小数点の小数点と区別します。

dotや dot0nscsimp, dot0simp, dot1simp, dotassoc, dotconstrules, dotdistrib, dotexptsimp, dotident, dotscrules. も参照してください。

Operators ·